Looking for VBA code to Put values in Column A and B when Column C is Not Empty

[bjnockle]

Looking for VBA code to put values in Column A and B when Column C is Not Empty. Reason for looking for VBA code is that the data set is 362656 and when a formula is used, the Excel Workbook is crashing. Formula works fine but it is crashing the Excel Workbook or getting stuck.

For example, column C2:C4 (Sales Year column) are not empty (C2=1999, C3=2000 and C4=2001), the VBA code should put in A3= 1st S and A4= 1st S and leave A2 = 1st S since A2 has a value already. Also, the VBA code should put in B3= 01103 and B4= 01103 and leave B2 = 01103 since B2 has a value already. The VBA code should do this for column A2:A500,000 and

****Desired solution sample is in F2:G25
****VBA Code solution should put values in A2:B362656. Please write the VBA to go beyond 362656 rows in case additional data is entered.

See sample file.

Thanks

[JohnTopley]

Sub JT_V01()

Dim arr
arr = [A1].CurrentRegion

Application.ScreenUpdating = False

For i = 2 To UBound(arr, 1)
    If arr(i, 1) = "" Then arr(i, 1) = arr(i - 1, 1): arr(i, 2) = arr(i - 1, 2)
Next i

[f1].Resize(UBound(arr, 1), UBound(arr, 2)) = arr

Application.ScreenUpdating = True


End Sub

[bjnockle]

JohnTopley: Outstanding solution. Works like a charm, JohnTopley. Thanks a lot.

[jolivanes]

You can try this on a copy of your workbook.
The empty looking cells in Column A are not empty. In the attachment anyway

Sub Maybe()
Dim lr As Long
lr = Cells(Rows.Count, 3).End(xlUp).Row
With Range("B2:B" & lr).SpecialCells(xlCellTypeBlanks)
        .FormulaR1C1 = "=R[-1]C"
        .Offset(, -1).FormulaR1C1 = "=R[-1]C"
End With
Range("A2:B" & lr).Value = Range("A2:B" & lr).Value
End Sub

[bjnockle]

jolivanes: Excellent solution, jolivanes. Works like a charm.

[jolivanes]

Thank you for letting us know that all is well now.

Good luck

[JohnTopley]

Thank you for the feedback and rep: much appreciated.