Choose particular values from a column using dialogue box and copy contents to email?

Columns A through H in table format. It should also contain few texts like: "Hello Project Owner, please find the below table and work on it"..

Pls keep in mind that the Email coulmns (E,F) need to be dynamic. Meaning to say, i need to find the column by its header and not by column E or F since there might be adds or deletes in columns during maintenance of the sheets.

To get things started.

Create a userform with a LisBox and a CommandButton in it.

Private Sub UserForm_Initialize()
    With Sheet1
        wCol = Application.Match("Program name", .Rows(1), 0)
        ListBox1.List = Application.Unique(.Columns(wCol))
    End With
End Sub

Private Sub CommandButton1_Click()
    Sheet2.Cells(1, 11).CurrentRegion.Offset(1).ClearContents
    With ListBox1
        For i = 1 To .ListCount - 1
            If .Selected(i) Then Sheet2.Range("K" & Rows.Count).End(xlUp).Offset(1) = .List(i, 0)
        Next
    End With
    With Sheet1
        .Cells(1).CurrentRegion.AdvancedFilter 2, Sheet2.Cells(1, 11).CurrentRegion, Sheet2.Cells(1).Resize(, 8)
    End With
    With Sheet2
        wColTo = .Cells(2, Application.Match("Project Owner Email", .Rows(1), 0))
        wColCC = .Cells(2, Application.Match("PM Email", .Rows(1), 0))
        .Columns.AutoFit
        .Cells(1).CurrentRegion.Copy
    End With
    With CreateObject("outlook.application").CreateItem(0)
        .to = wColTo
        .cc = wColCC
        .Subject = "Hello Project Owner, please find the below table and work on it"
        With .GetInspector
            .Display
            .WordEditor.Range(0, 0).Paste
        End With
    End With
    Application.CutCopyMode = False
End Sub

1. K1:K2 is the Criteria range for the AdvancedFilter to work properly.
2. Make sure the Columnheaders on Output sheet are exactly the same as in Input sheet. (best is to copy them from 1 sheet to the other)
This is how it should look like.
Attachment 888602