VBA Sleep code time interval question

Didn't think of trying that given it was already True to start with.

Thank you guys for the replies, I was going to attach the sample but I tried ByteMarks solution and it works, no need for the separate coding on another module. I like that if I want to change the interval I only need to go to the top and change the .25 to whatever I need. Thank you so much for this solution. I really didn't think it was possible to go for less than 1 second, so this is great to know as I have some creative ideas I might put in place that would utilize this feature.

Happy to have contributed.

Actually after thinking, I am curious - would there be a lot of code needed to also change a Shape's size as well? Ultimately, this is the code I have with the color change to flash different colors a few times:

Private Sub Worksheet_Change(ByVal Target As Range)
    Const numSecs As Double = 0.25  'quarter of a second
    If Intersect(Target, Range("J34")) Is Nothing Then Exit Sub
    MsgBox "REMINDER: After filling out info for this row, click the Archive and Reset Sheet button", vbOKOnly
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
End Sub

How about if you wanted to do something like this(see underlined):

Private Sub Worksheet_Change(ByVal Target As Range)
    Const numSecs As Double = 0.25  'quarter of a second
    If Intersect(Target, Range("J34")) Is Nothing Then Exit Sub
    MsgBox "REMINDER: After filling out info for this row, click the Archive and Reset Sheet button", vbOKOnly
    Increase Shape Size
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbRed
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    Shapes("Archive_Reset").Fill.ForeColor.RGB = vbBlue
    Decrease shape size back to original size
    Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
    
End Sub

Original height is 1.12" and width is 1.47" What if we wanted to go to 1.25" and 1.69" respectively?

something like this:

Private Sub Worksheet_Change(ByVal Target As Range)
    Const numSecs As Double = 0.25  'quarter of a second
    Const hSmall As Double = 1.12: Const hBig As Double = 1.25
    Const wSmall As Double = 1.47: Const wBig As Double = 1.69
   
    If Intersect(Target, Range("J34")) Is Nothing Then Exit Sub
    MsgBox "REMINDER: After filling out info for this row, click the Archive and Reset Sheet button", vbOKOnly
    With Shapes("Archive_Reset")
        ' Increase Shape Size
        .Height = hBig: .Width = wBig
        'Flash colours
        For i = 1 To 3
            .Fill.ForeColor.RGB = vbRed: Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
            .Fill.ForeColor.RGB = vbBlue: Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
            DoEvents
        Next
        'Decrease Shape Size
        .Height = hSmall: .Width = wSmall
    End With
End Sub

Ok ByteMarks, I pasted your code over mine, but it didn't behave as expected. It made the shape very tiny. I am attaching a sample copy with your code pasted. If you type anything in J34 and then click out of the cell or press enter, it will run the event code.(The same goes if you delete what you type in that cell). I don't know if I gave you bad info, but I had right-clicked the shape and went to size and properties and had copied what was there. Not sure if there was somewhere else I should have looked or if sizes are handled differently in VBA?

Sorry, I missed that it was in inches.
Convert the inches to points:

Private Sub Worksheet_Change(ByVal Target As Range)
    Const numSecs As Double = 0.25  'quarter of a second
    
    With Application
        Dim hSmall As Double: hSmall = .InchesToPoints(1.12)
        Dim hBig As Double: hBig = .InchesToPoints(1.25)
        Dim wSmall As Double: wSmall = .InchesToPoints(1.47)
        Dim wBig As Double: wBig = .InchesToPoints(1.69)
    End With
   
    If Intersect(Target, Range("J34")) Is Nothing Then Exit Sub
    MsgBox "REMINDER: After filling out info for this row, click the Archive and Reset Sheet button", vbOKOnly
    With Shapes("Archive_Reset")
        ' Increase Shape Size
        .Height = hBig: .Width = wBig
        'Flash colours
        For i = 1 To 3
            .Fill.ForeColor.RGB = vbRed: Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
            .Fill.ForeColor.RGB = vbBlue: Application.Wait CDbl(Date) + (Timer + numSecs) / 86400
            DoEvents
        Next
        'Decrease Shape Size
        .Height = hSmall: .Width = wSmall
    End With
End Sub

Yes. Change the 3 to however many flashes. You could even use a variable and change the number of flashes depending on the cell or cell value.