Hi, Posting this for searchable info, and in case any offer of explanation of, or better workaround/fix ?


You can get into state where you get :: Microsoft Excel "Document not saved" window displayed,
and so unable to save without closing / reopening workbook, as a result of having workbook changing code run in a BeforeSave event.

E.g.

If for some reason you wish to more manually control a Save As then you might have code such as 

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim strSaveAsMy As String
    
    If SaveAsUI Then
        'just for this demo toggling name, you're more likely to have the likes of strSaveAsMy = Application.GetSaveAsFilename(...)
        strSaveAsMy = toggleName(ThisWorkbook.FullName)     
        On Error Resume Next
        Application.EnableEvents = False
        
        ThisWorkbook.SaveAs Filename:=strSaveAsMy

        ThisWorkbook.ActiveSheet.Range("A1").Value = "BS " & CStr(Now())
        
        Application.EnableEvents = True
        On Error GoTo 0
        Cancel = True
    End If
End Sub

Public Function toggleName(ByVal strFilename As String) As String
    ' just adds or removes a "2" from the supplied filename/path (pre-file-extension)
    Dim arrFN As Variant
    toggleName = strFilename
    arrFN = Split(strFilename, ".")
    If Right(arrFN(UBound(arrFN) - 1), 1) = "2" Then
        arrFN(UBound(arrFN) - 1) = Left(arrFN(UBound(arrFN) - 1), Len(arrFN(UBound(arrFN) - 1)) - 1)
    Else
        arrFN(UBound(arrFN) - 1) = arrFN(UBound(arrFN) - 1) & "2"
    End If
    toggleName = Join(arrFN, ".")
End Function
Whilst this will run okay, the workbook is then in a state where any attempt to Save e.g. Ctrl-S results in the Microsoft Excel "Document not saved" window and fails to save, and has to be closed and re-opened to make further changes.

This is the result of having Workbook changing code being run after your own ThisWorkbook.SaveAs .
i.e. ThisWorkbook.ActiveSheet.Range("A1").Value = "BS " & CStr(Now()) in above example


However it appears that the Workbook_AfterSave event is triggered with parameter Success=False , due to the Cancel=True processing.
This means that the following can achieve the post save workbook content alteration and does not cause this problematic state.

E.g.

Private gDoActionAfterSave As Boolean
'

Private Sub Workbook_AfterSave(ByVal Success As Boolean)
    If gDoActionAfterSave And Not Success Then
        ThisWorkbook.ActiveSheet.Range("A1").Value = "AS " & CStr(Now())
    End If
    gDoActionAfterSave = False
End Sub

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim strSaveAsMy As String
    
    If SaveAsUI Then
        strSaveAsMy = toggleName(ThisWorkbook.FullName)
        On Error Resume Next
        Application.EnableEvents = False
        
        ThisWorkbook.SaveAs Filename:=strSaveAsMy
        ' ** ANY WORKBOOK CHANGING CODE AFTER HERE RESULTS IN THE SUBSEQUENT Document not Saved BEHAVIOUR
        
        'E.g.  ThisWorkbook.ActiveSheet.Range("A1").Value = "BS " & CStr(Now())
        
        Application.EnableEvents = True
        On Error GoTo 0
        gDoActionAfterSave = True       ' so post save change in AfterSave event actioned
        Cancel = True
    End If
End Sub

Hope this is useful, please post any additional info..