How evaluate clicked commandbuttons on form

Very quick and brief response here:

Can you just use Option Buttons?

See revised code attachedForm with group buttons.xlsmForm with group buttons.xlsm

The Public variable bo??? are useless, just checking the text color button …

To class module CommandButtonClass :

PHP Code: 

Sub CommandButtonGroup_Click()
    UserForm.cmdButtonAAA.ForeColor = 0
    UserForm.cmdButtonBBB.ForeColor = 0
    UserForm.cmdButtonCCC.ForeColor = 0
    CommandButtonGroup.ForeColor = vbBlue
End Sub 


To module UserForm :

PHP Code: 

Private Sub cmdValues_Click()
    MsgBox "Button AAA : " & (cmdButtonAAA.ForeColor = vbBlue) & vbLf & vbLf & _
           "Button BBB : " & (cmdButtonBBB.ForeColor = vbBlue) & vbLf & vbLf & _
           "Button CCC : " & (cmdButtonCCC.ForeColor = vbBlue), , "Selected status"
End Sub 


► Do you like it ? ► ► So thanks to click on bottom left star icon « ★ Add Reputation » ! ◄ ◄

Many roads lead to Rome.
This is another one, a bit more winding than the road proposal shown by Marc L, but it works on a similar principle. I'm just listing the revised procedures.

In UserForm module:

Private Sub cmdValues_Click()
  Dim i As Long
  Dim strVal As String
    
    For i = 1 To UBound(Buttons)
      strVal = strVal & CBool(Buttons(i).CommandButtonGroup.Tag) & vbLf
    Next i
    
    MsgBox "The Values of the boxes are: " & vbLf & strVal

End Sub


Private Sub UserForm_Initialize()
  
    Dim Ctrl        As Control
    Dim Count       As Integer

    For Each Ctrl In Me.frmButtons.Controls
        If TypeName(Ctrl) = "CommandButton" Then
            Count = Count + 1
            ReDim Preserve Buttons(1 To Count)
            Set Buttons(Count).CommandButtonGroup = Ctrl
            
            'Set each button to False (0)
            Buttons(Count).CommandButtonGroup.Tag = 0
        End If
    Next Ctrl
End Sub

In class module :

Sub CommandButtonGroup_Click()

    Dim varButtonChoice As Variant
    Dim Ctrl        As Control
    Dim Fram As MSForms.Frame

    varButtonChoice = CommandButtonGroup.Caption
    Set Fram = CommandButtonGroup.Parent
    
    MsgBox "You pressed " & varButtonChoice
    
    'Set all buttons to False (0)
    For Each Ctrl In Fram.Controls
      If TypeName(Ctrl) = "CommandButton" Then
        Ctrl.Tag = 0
      End If
    Next Ctrl
    
    'Set clicked button to True (-1)
    CommandButtonGroup.Tag = -1
    
End Sub

Artik

Lastjp, Marc L, torachan and Artik, thank you all very much for your replies. I combined a few of the answers and it works fine: the buttons as well as the changing of the color. Why not OptionButtons? The form in my attachment is just al smal part of a larger form with several types of controls and it looked quite chaotic. But this is perfect ;-) - thanks, Jan