Is there a way to put the row number on a value found on a worksheet into a textbox?

So let's say I have a worksheet with a column filled with phone numbers. I have a userform with a text box that I will be typing in a phone number into, and I want a different text box to reflect the number of the row that the phone number is found in on the worksheet.

I've looked around, but all the codes I've seen people write are very specific to their needs and much different from another.

Found a solution that worked!

 Dim row As Range
Set row = ws.Cells.Find(What:=MAINNUMTEXTBOX.Value, LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
ROWNUMBERTEXTBOX.Value = row.row

Yet another solution.

Code in the form module:

Option Explicit

Dim vPhones         As Variant


Private Sub txtPhone_Change()
    Dim v           As Variant

    v = Application.Match(Me.txtPhone.Value, vPhones, 0)

    If IsError(v) Then
        Me.lblDataRow.Caption = vbNullString
        Me.lblSheetRow.Caption = vbNullString
    Else
        Me.lblDataRow.Caption = v
        Me.lblSheetRow.Caption = v + 3
    End If

End Sub


Private Sub UserForm_Initialize()
    With Me.lblDataRow
        .Caption = vbNullString
        .TextAlign = fmTextAlignCenter
        .Font.Bold = True
    End With

    With Me.lblSheetRow
        .Caption = vbNullString
        .TextAlign = fmTextAlignCenter
        .Font.Bold = True
    End With

    Me.txtPhone.Value = vbNullString

    With ActiveSheet.Range("A3").CurrentRegion
        vPhones = .Offset(1).Resize(.Rows.Count - 1).Columns(1).Cells.Value
    End With
End Sub

Artik