Macro that inserts page breaks into a monthly report when name changes occur in column C

The attached monthly report is exported from another system (non-MS) and will contain the names of 250-300 individuals. I want a macro that will automatically insert page breaks in column C when the name changes versus doing it manually myself. The size of the report would make manual insertion counter-productive.

Possibly...

Sub Test()
    Dim v As Variant
    v = Application.Transpose(Sheet1.UsedRange.Columns(3).Value)
    
    Dim i As Long
    With CreateObject("Scripting.Dictionary")
        For i = LBound(v) To UBound(v)
            If Not IsEmpty(v(i)) Then .Item(v(i)) = Empty
        Next i
        v = .keys
    End With
    
    Dim c As Range
    For i = 1 To UBound(v)
        Set c = Sheet1.UsedRange.Find(v(i))
        Sheet1.Rows(c.Row).PageBreak = xlPageBreakManual
    Next i
End Sub

Thank you for the response and help.

The macro works to a certain extent. It inserts a page break BELOW the "Single restoration codes" heading (see attachment).
Is there a way to have the page break inserted above the row so that the heading is included with the next student's name?

another approach

Sub Test()
Dim pn As Range
Dim cn As Range
Dim i As Long, lr As Long, r As Long

With ActiveSheet
    On Error Resume Next
    lr = Cells.Find(What:="*", After:=.Cells(1, 1), LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious, SearchFormat:=False).Row
    On Error GoTo 0
    If lr = 0 Then Exit Sub

    For i = lr To 2 Step -1
        If .Range("a" & i) = "" Then .Range("a" & i).EntireRow.Delete
    Next

    On Error Resume Next
    lr = .Cells.Find(What:="*", After:=.Cells(1, 1), LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious, SearchFormat:=False).Row
    On Error GoTo 0
    
    If lr > 0 Then
        .ResetAllPageBreaks
        With .PageSetup
            .PrintArea = "A1:M" & lr
            .Zoom = False
            .FitToPagesWide = 1
            .FitToPagesTall = False
        End With
        For r = 5 To lr
            If .Range("A" & r).MergeArea.Cells.Count = 1 Then
                Set cn = .Range("C" & r)
                If Not pn Is Nothing Then
                    If cn.Value <> pn.Value Then
                        .HPageBreaks.Add before:=pn.Offset(1, 0)
                    End If
                End If
                Set pn = cn
            End If
        Next
    End If
End With
End Sub

Possibly...

Sub Test()
    Dim v As Variant
    v = Application.Transpose(Sheet1.UsedRange.Columns(3).Value)
    
    Dim i As Long
    With CreateObject("Scripting.Dictionary")
        For i = LBound(v) To UBound(v)
            If Not IsEmpty(v(i)) Then .Item(v(i)) = Empty
        Next i
        v = .keys
    End With
    
    Dim c As Range
    For i = 1 To UBound(v)
        Set c = Sheet1.UsedRange.Find(v(i))
        Sheet1.Rows(c.Row-1).PageBreak = xlPageBreakManual
    Next i
End Sub