Creating an Excel Template for each month

i'm getting an error (upload failed) trying to upload an example. basically i have a workbook for September and the worksheet tabs at the bottom are labeled Thursday Sept 1, Friday Sept 2, and so on until the end of the month. i tried googling code to automate this via vba but have failed. could i please get some help with this?

aloha,

Gavin

Hi have a look at this it should do what your looking for

https://www.mrexcel.com/board/thread...-month.674087/

Sub CreateSheets()
Dim strDate As String
Dim NumDays As Long
Dim i As Long
Dim sh As Object
Dim wsBase As Worksheet
On Error GoTo EndIt
    
' The Do statement to captures Month/Year via Input Box
' and return number of days in the month to the NumDays variable
    Do
        strDate = Application.InputBox( _
            Prompt:="Please enter month and year: mm/yyyy", _
            Title:="Month and Year", _
            Default:=Format(Date, "mm/yyyy"), _
            Type:=2)
 
        If strDate = "False" Then Exit Sub
        If IsDate(strDate) Then Exit Do
        If MsgBox("Please enter a valid date, such as ""01/2010""." _
            & vbLf & vbLf & "Shall we try again?", vbYesNo + vbExclamation, _
            "Invalid Date") = vbNo Then End
    Loop
    
    Application.ScreenUpdating = False
    NumDays = Day(DateSerial(Year(strDate), Month(strDate) + 1, 0))
    Set wsBase = Sheets("Template")
    
' For each day, the For statement below copies the template sheet 'n' times
    For i = 1 To NumDays
        wsBase.Copy After:=Sheets(Sheets.Count)
        ActiveSheet.Name = Format(DateSerial(Year(strDate), Month(strDate), i), "ddd mmm dd yyyy")
    Next i
EndIt:
    Application.ScreenUpdating = True
End Sub

that worked like a charm!! thank you so much!!