Loop through a DIM variable

This will reference every sheet in the workbook that contains the code .

Public Sub RefEachSheetInWkBk()
    Dim sh As Worksheet
    Dim cellValue As Variant

    For Each sh In ThisWorkbook.Sheets
        cellValue = sh.Range("A1").Value
    Next sh
End Sub

this code will loop thru specific named sheets

Sub LoopDIM()
    Dim shName
    Dim cellValue As Variant

    Const SHEET_NAMES As String = "Tab1,Tab2,Tab3,Tab4"

    For Each shName In Split(SHEET_NAMES, ",")
        With Sheets(shName)
            .Range("A1").Value = "test"
            cellValue = .Range("A1").Value
        End With
    Next shName

End Sub

HERE'S EXCELLENT REFERENCE ON SUBJECT : https://docs.microsoft.com/en-us/off...lls-and-ranges

if this code has helped please consider clicking "add reputation" , thx

If you want to loop through specific sheets then you could use something like the below:

Sub LoopDIM()
    Dim mSheets As Variant, i As Integer
    
    mSheets = Split("Tab1,Tab2,Tab3,Tab4", ",")

    For i = 0 To UBound(mSheets)
        Sheets(mSheets(i)).Range("A1") = "Hello World"
    Next
End Sub

Also no need for select, see how tha above can write to each sheet without selecting.

This solution loops thru each sheet name AND checks that the sheet exists before accessing it.
If the sheet does not exist the macro tells you so and exits the process.
This example uses a re-usable function to perform a "Safe Set" (ie. safeSetSheet)
In MY ACTUAL CODE I almost always use the "Safe Set" method
Without a "Safe Set" method your macro will crash if sheet does not exist

Sub LoopDIM()
    Dim shName
    Dim cellValue As Variant
    Dim currSh As Worksheet

    Const SHEET_NAMES As String = "Tab1,Tab2,Tab3,Tab4"

    For Each shName In Split(SHEET_NAMES, ",")
    
        Set currSh = safeSetSheet(ThisWorkbook.Name, CStr(shName))
        If currSh Is Nothing Then Exit Sub
        With currSh
            .Range("A1").Value = "test"
            cellValue = .Range("A1").Value
        End With
    Next shName

End Sub

Public Function safeSetSheet(wkBkName As String, sheetName As String) As Worksheet
    Dim wkBk As Workbook
    Dim wkSh As Worksheet
    Dim errMsg As String, reason As String

    Const REASON_PREFIX As String = "Could not locate required "

    On Error Resume Next
    Set wkBk = Workbooks(wkBkName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "workbook."
        GoTo errHandler
    End If

    Set safeSetSheet = wkBk.Sheets(sheetName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "worksheet."
        GoTo errHandler
    End If

    Exit Function
errHandler:
    errMsg = reason & vbNewLine
    errMsg = errMsg & "Workbook:" & vbTab & wkBkName & vbNewLine
    errMsg = errMsg & "Worksheet:" & vbTab & sheetName & vbNewLine
    MsgBox errMsg, vbCritical, "Process Aborted"
End Function

HERE'S EXCELLENT REFERENCE ON SUBJECT : https://docs.microsoft.com/en-us/off...lls-and-ranges

if this code has helped please consider clicking "add reputation" , thx

Accessing many sheets at once
This example uses a re-usable function to perform a "Safe Set" (ie. safeSetSheet)
In MY ACTUAL CODE I almost always use the "Safe Set" method
Without a "Safe Set" method your macro will crash if sheet does not exist

WITH SAFESET

Sub accessManySheets()
    Dim AccSh As Worksheet, CostSh As Worksheet, InvSh As Worksheet
    
    'set reference to accounting sheet in the workbook that contains macro
    Set AccSh = safeSetSheet(ThisWorkbook.Name, "Sheet1")
    If AccSh = Nothing Then Exit Sub
    
    'set reference to cost sheet in the active workbook
    Set CostSh = safeSetSheet(ActiveWorkbook.Name, "Sheet2")
    If CostSh = Nothing Then Exit Sub

    
    'set reference to Invoice sheet in workbook called book1
    Set InvSh = safeSetSheet(Workbooks("book1.xlsx"), "Sheet2")
    If InvSh = Nothing Then Exit Sub
    
    ' assign Invoice sheet value from Cost sheet
    InvSh.Range("A1").Value = CostSh.Range("B1").Value

End Sub

Public Function safeSetSheet(wkBkName As String, sheetName As String) As Worksheet
    Dim wkBk As Workbook
    Dim wkSh As Worksheet
    Dim errMsg As String, reason As String

    Const REASON_PREFIX As String = "Could not locate required "

    On Error Resume Next
    Set wkBk = Workbooks(wkBkName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "workbook."
        GoTo errHandler
    End If

    Set safeSetSheet = wkBk.Sheets(sheetName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "worksheet."
        GoTo errHandler
    End If

    Exit Function
errHandler:
    errMsg = reason & vbNewLine
    errMsg = errMsg & "Workbook:" & vbTab & wkBkName & vbNewLine
    errMsg = errMsg & "Worksheet:" & vbTab & sheetName & vbNewLine
    MsgBox errMsg, vbCritical, "Process Aborted"
End Function

WITHOUT SAFESET
NOTE: Without a "Safe Set" method your macro will crash if sheet does not exist

Sub accessManySheets()
    Dim AccSh As Worksheet, CostSh As Worksheet, InvSh As Worksheet
    
    'set reference to accounting sheet in the workbook that contains macro
    Set AccSh = ThisWorkbook.Sheets("Sheet1")
    
    'set reference to cost sheet in the active workbook
    Set CostSh = ActiveWorkbook.Sheets("Sheet2")
   
    'set reference to Invoice sheet in workbook called book1
    Set InvSh = Workbooks("book1.xlsx").Sheets("Sheet2")
    
    ' assign Invoice sheet value from Cost sheet
    InvSh.Range("A1").Value = CostSh.Range("B1").Value

End Sub

HERE'S EXCELLENT REFERENCE ON SUBJECT : https://docs.microsoft.com/en-us/off...lls-and-ranges

if this code has helped please consider clicking "add reputation" , thx

Four demos on referencing the same sheet multiple times ( from worst to best)

Public Sub demo1()
    Sheets("Sheet1").Range("A1").Value = "Test"
    Sheets("Sheet1").Range("A2").Value = "Test"
    Sheets("Sheet1").Range("A3").Value = "Test"
End Sub

Public Sub demo2()
    With Sheets("Sheet1")
        .Range("A1").Value = "Test"
        .Range("A2").Value = "Test"
        .Range("A3").Value = "Test"
    End With
End Sub

note the practice of giving the sheet Var a meaningful name that helps indicate intent (eg. its the target sheet )

Public Sub demo3()
Dim targetSh As Worksheet

Set targetSh = Sheets("Sheet1")

    With targetSh
        .Range("A1").Value = "Test"
        .Range("A2").Value = "Test"
        .Range("A3").Value = "Test"
    End With
End Sub

Public Sub demo4()
Dim targetSh As Worksheet

Set targetSh = safeSetSheet(ThisWorkbook.Name, "Sheet1")
If targetSh Is Nothing Then Exit Sub

    With targetSh
        .Range("A1").Value = "Test"
        .Range("A2").Value = "Test"
        .Range("A3").Value = "Test"
    End With
End Sub

Public Function safeSetSheet(wkBkName As String, sheetName As String) As Worksheet
    Dim wkBk As Workbook
    Dim wkSh As Worksheet
    Dim errMsg As String, reason As String

    Const REASON_PREFIX As String = "Could not locate required "

    On Error Resume Next
    Set wkBk = Workbooks(wkBkName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "workbook."
        GoTo errHandler
    End If

    Set safeSetSheet = wkBk.Sheets(sheetName)
    If Err.Number > 0 Then
        reason = REASON_PREFIX & "worksheet."
        GoTo errHandler
    End If

    Exit Function
errHandler:
    errMsg = reason & vbNewLine
    errMsg = errMsg & "Workbook:" & vbTab & wkBkName & vbNewLine
    errMsg = errMsg & "Worksheet:" & vbTab & sheetName & vbNewLine
    MsgBox errMsg, vbCritical, "Process Aborted"
End Function

if this code has helped please consider clicking "add reputation" , thx