Run time error 1004

[chrisellis250]

Hi all,

I have been running this code with no errors for a while, but this keeps popping up now and I am unsure why:

Sub Procedure14()
'Copy to IMEI table
Application.ScreenUpdating = False
Sheets("IMEI").Select
    Range("A2").Select
    Range(Selection, Selection.End(xlDown)).Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Start").Select
    Range("L3").Select
    ActiveSheet.Paste
    Sheets("IMEI").Select
    Range("B2").Select
    Range(Selection, Selection.End(xlDown)).Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Start").Select
    Range("N3").Select
    ActiveSheet.Paste
        
Application.ScreenUpdating = True

End Sub

I am getting "Run-time error '1004': You can't paste this here because the Copy area and paste area aren't the same size. Select just one cell in the paste area or an area that's the same size, and try pasting again.

With this line highlighted:

ActiveSheet.Paste

Any ideas why?

[BadlySpelledBuoy]

If there is just the one value in column B of the IMEI sheet, i.e. something in B2 but nothing in B3 or below, your xlDown command will copy from there to the very last row in the worksheet. When you try and paste that range into the Start sheet starting at row 3, it will go beyond the limit of Excel and it throws up an error. Microsoft are very well known for their error messages not being particularly helpful, and this is a prime example.

Give this version a try. It should do all your code does but will cope with there being just one value in either column.

Sub Procedure14()
    Application.ScreenUpdating = False
    
    With Sheets("IMEI")
        .Range("A2:A" & .Cells(Rows.Count, "A").End(xlUp).Row).Copy Sheets("Start").Range("L3")
        .Range("B2:B" & .Cells(Rows.Count, "B").End(xlUp).Row).Copy Sheets("Start").Range("N3")
    End With
    
    Application.ScreenUpdating = True
End Sub

It will obviously still fall over if you have values in EVERY row, but that's unlikely.

BSB

[chrisellis250]

Excellent! Thank you so much BadlySpelledBuoy!

[BadlySpelledBuoy]

Happy to help

BSB