macro to copy sheet to end with sheet name current date

Hi eugz,

Not sure why you'd create a tab for every day but this will do the job:

Option Explicit
Sub Macro1()
    
    Dim ws As Worksheet
    
    ActiveSheet.Copy After:=Sheets(Sheets.Count)
    Set ws = Sheets(Sheets.Count)
    ws.Name = Format(Date, "mm-dd-yy")
    
End Sub

Regards,

Robert

Hi Robert. Thanks for reply.
Your code works awesome. But how to modify it to give ability for user change name in case if user will create some sheets at the same day? How to validate duplicate sheet name? Just inform user that sheet with same name exists and keep sheet name selected to give user ability to modify a sheet name

Thanks

Try this:

Option Explicit
Sub Macro1()
    
    Dim ws As Worksheet
    Dim strTabName As String
    
    Application.ScreenUpdating = False
    
    On Error Resume Next
        Set ws = ThisWorkbook.Sheets(CStr(Format(Date, "mm-dd-yy")))
    On Error GoTo 0
    If Not ws Is Nothing Then
        strTabName = Application.InputBox("There is already a tab called """ & Format(Date, "mm-dd-yy") & """ in the workbook." & vbNewLine & "Please enter a different name:", "Tab Name Editor")
        If strTabName = "False" Then
            Application.ScreenUpdating = True
            Exit Sub
        End If
        Set ws = Nothing
    End If
    
    ActiveSheet.Copy After:=Sheets(Sheets.Count)
    Set ws = Sheets(Sheets.Count)
    ws.Name = IIf(Len(strTabName) > 0, strTabName, Format(Date, "mm-dd-yy"))
    
    Application.ScreenUpdating = True
    
End Sub