Sorting an multilevel / hierarchical column

I need to sort a multi-thousand records table and here is an extract;

Seq
1
1.1
1.111
2
1.1.2
1.1.2.1

so it will end

Seq
1
1.1
1.1.2
1.1.2.1
1.111
2

It can be up to 7 levels. What would be the best strategy? I would be fine to add 7 columns as sublevels, I just don't know how to populate them.

TIA.

2

I found a way to do it. It now works and I sort on columns Order1...Order11.

I can't post the code here as I get this message (no SQL code)

Block details:
Your IP: 216.208.79.194
URL: http://www.excelforum.com/newreply.p...eply&t=1367723
Your Browser: Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/96.0.4664.110 Safari/537.36
Block ID: SQLi84
Block reason: SQL injection was detected and blocked.
Time: 2022-01-06 13:43:36
Server ID: 14015

Assuming header in A1 and sort from A2 onwards.

Sub test()
    Dim a, i As Long, ii As Long, iii As Long, temp
    With Range("a1", Range("a" & Rows.Count).End(xlUp))
        a = .Value
        ReDim Preserve a(1 To UBound(a, 1), 1 To 2)
        For i = 2 To UBound(a, 1)
            a(i, UBound(a, 2)) = GetSortVal(a(i, 1))
        Next
        For i = 2 To UBound(a, 1) - 1
            For ii = i + 1 To UBound(a, 1)
                If a(i, UBound(a, 2)) > a(ii, UBound(a, 2)) Then
                    For iii = 1 To UBound(a, 2)
                        temp = a(i, iii): a(i, iii) = a(ii, iii): a(ii, iii) = temp
                    Next
                End If
            Next
        Next
        .Value = a
    End With
End Sub

Function GetSortVal(ByVal txt As String) As String
    Dim i As Long, m As Object
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "\d+"
        If .test(txt) Then
            For i = .Execute(txt).Count - 1 To 0 Step -1
                Set m = .Execute(txt)(i)
                txt = Application.Replace(txt, m.firstindex + 1, m.Length, Format$(m.Value, String(4, "0")))
            Next
        End If
    End With
    GetSortVal = txt
End Function

Thanks for the code. Yes I thought that none of our drawings had more than 99 components but this was a wrong assessment.

If it is not working, upload the workbook showing before/after.