Do while running slow

Created a 'do while' code, which runs very slow.

Below is the labelClass code
do while.PNG

Here is the do while code
dowhile.PNG

Appreciate any feedback

Regards
Margo

What is the activecell when you launch the macro ?
What is the purpose of the macro ?

See file attached

Maybe this:

Sub sUpdateStatus()

Dim lLR As Long, i As Long
Dim lStockCol As Long
Dim Status As Long

lStockCol = Application.WorksheetFunction.Match("Stock on Hand", Range("A1").EntireRow, 0)
lLR = Cells(Rows.Count, lStockCol).End(xlUp).Row

Application.ScreenUpdating = False
For i = 2 To lLR
    Status = Cells(i, lStockCol).Value
    Cells(i, lStockCol + 1).Value = flabelClass(Status)
Next 'i
Application.ScreenUpdating = True

End Sub

Public Function flabelClass(Status As Long) As String

Select Case Status
Case Is = 0
    flabelClass = "Not In Stock"
Case 1 To 4
    flabelClass = "Very Limited Stock"
Case 5 To 29
    flabelClass = "limited stock"
Case Is >= 30
    flabelClass = "In Stock"
End Select
   
End Function

Your code is slow because you select cells. ScreenUpdating = False masks the issue because the screen is not being redrawn. That said, if the volume of data is small, it does resolve your problem (as you state).

I suspect the original code only appears to be slow because you are watching the active cell move down the screen and the cells being updated.

Merci Beaucoup et bonne année

Merci, toi aussi

By the way, you got all explanations from TMS about how slow could be your code, but there is still some improvement to do, working with memory.
It could be useful for some others,

Just for fun, this uses arrays so the bulk of the work is done in memory. It locates the stock in hand column, stores the values in an attay, loops through it and creates another array of "labels", and outputs it the next available column. It should be virtually instantaneous.

Option Explicit

Sub sUpdateStatus_v2()

Dim lNC As Long, lLR As Long, i As Long
Dim lStockCol As Long
Dim vStatus, vLabel

lNC = Cells(2, Columns.Count).End(xlToLeft).Column + 1
lStockCol = Application.WorksheetFunction.Match("Stock on Hand", Range("A1").EntireRow, 0)
lLR = Cells(Rows.Count, lStockCol).End(xlUp).Row

vStatus = Range(Cells(2, lStockCol), Cells(lLR, lStockCol))
ReDim vLabel(LBound(vStatus) To UBound(vStatus))

For i = LBound(vStatus) To UBound(vStatus)
    vLabel(i) = flabelClass(vStatus(i, 1))
Next 'i

Cells(2, lNC).Resize(UBound(vStatus)) = _
    Application.Transpose(vLabel)

End Sub

Public Function flabelClass(Status) As String

Select Case Status
Case Is = 0
    flabelClass = "Not In Stock"
Case 1 To 4
    flabelClass = "Very Limited Stock"
Case 5 To 29
    flabelClass = "limited stock"
Case Is >= 30
    flabelClass = "In Stock"
End Select
   
End Function