VBA MAcro for non-selected worksheets to be hidden

[vakbel]

Hello dear friends,

I've got several worksheet tabs in my workbook, I am currently selecting just 3 of them (out of 33 for example), I would like to hide all worksheets except the ones that I've selected (so it is vice-versa for hiding the selected ones).

this is the code below I am trying express for the desired result (of course not working at all), if any of you experts could direct me a little bit, it'd be highly appreciated:


Sub HidingUnSelectedSheets()

Dim ws As Worksheet

Sheets(Array("Sheet5", "Sheet6")).Select

For Each ws In ThisWorkbook.Windows(1).SelectedSheets
If Not ws Is Selected Then
ws.Visible = False
End If
Next

End Sub

[Mumps1]

Try:

Sub HidingUnSelectedSheets()
    Application.ScreenUpdating = False
    Dim ws As Worksheet
    For Each ws In Sheets(Array("Sheet5", "Sheet6"))
        ws.Visible = False
    Next ws
    Application.ScreenUpdating = True
End Sub

[vakbel]

Thank you for your guidance and quick response.
I'm actually ok with hiding the "selected" sheets, rather I was trying to hide the other sheets that were not cited in sheets(array).

[jindon]

Hello dear friends,
I would like to hide all worksheets except the ones that I've selected (so it is vice-versa for hiding the selected ones).

Not really sure about it tough.

Sub HideOther()
    Dim myWs, i As Long, ws As Worksheet, x
    With ActiveWindow.SelectedSheets
        ReDim myWs(1 To .Count)
        For i = 1 To .Count
            myWs(i) = .Item(i).Name
        Next
    End With
    For Each ws In Worksheets
        x = Application.Match(ws.Name, myWs, 0)
        If IsError(x) Then ws.Visible = 0
    Next
End Sub

Sub HideSelected()
    Dim myWs, i As Long, ws As Worksheet, x
    With ActiveWindow.SelectedSheets
        ReDim myWs(1 To .Count)
        For i = 1 To .Count
            myWs(i) = .Item(i).Name
        Next
    End With
    For Each ws In Worksheets
        x = Application.Match(ws.Name, myWs, 0)
        If IsError(x) Then
            ws.Visible = 1
        Else
            ws.Visible = 0
        End If
    Next
End Sub

[vakbel]

Thank you very much Jindon.

It works just fine and perfectly.
Really appreciated.