Copy table from excel and send as html email body

Hi

This is more less what your looking for:

Dim OutApp As Object, OutMail As Object
Dim rng As Range
Dim d As Date
Function RangetoHTML(rng As Range)
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
    TempWB.Close savechanges:=False
    Kill TempFile
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function
Sub CreateNewEmailWithHTMLRangePasted(MyRng As Range, EmailTo1 As String, EmailTo2 As String)
    Set rng = Nothing
    On Error Resume Next
    Set rng = MyRng
    On Error GoTo 0
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    strbody = RangetoHTML(rng)
    Set rng = Sheet1.Range("A51:G55") 'add deadlines
    strbody = strbody & RangetoHTML(rng)
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
    With OutMail
        .To = Sheet1.Range(EmailTo1).Value & ";" & Sheet1.Range(EmailTo2).Value
        .CC = ""
        .BCC = ""
        .Subject = "That your table and deadlines"
        .HTMLBody = "Hi," & vbNewLine & vbNewLine & _
                        "Below are the set of data which needs your support in the workflow." & vbNewLine & vbNewLine & strbody
        .Display '.Send
    End With
    On Error GoTo 0
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Sub SendEmails()
 CreateNewEmailWithHTMLRangePasted MyRng:=Sheet1.Range("A2:S17"), EmailTo1:="I53", EmailTo2:="K53"
 CreateNewEmailWithHTMLRangePasted MyRng:=Sheet1.Range("A18:S33"), EmailTo1:="I54", EmailTo2:="K54"
 CreateNewEmailWithHTMLRangePasted MyRng:=Sheet1.Range("A34:S49"), EmailTo1:="I55", EmailTo2:="K55"
End Sub

Paste in Module and assign SendEmails into button (already done in attached file).
That needs some tweaks to calculate and declare ranges only for non-empty lines.

p.s. *LANG PL=ON* Pozdrowienia dla stolicy *LANG PL=OFF*