VBA Code for Discreet 2 Way Link Between Cells on Same Sheet

Hi folks.
I wish to create discreet two-way links between two ranges of cells in the same sheet. Range 1 is A41:A56 and Range 2 is A61:A76. I would like to create a situation in which whenever A41 is changed, it also changes A61, and vice versa. Ditto for A42 changing and changed by A57...and so on. I've tried a variety of methods using worksheet_change, but am having trouble getting the bi-directionality to work. Also, when I change any of the A41-A56 cells, it produces the same change in the entire Range 2 group, rather than the single cell that is its counterpart. Any help with this would be greatly appreciated.

Paste in Sheet1 :

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Integer
If Not Application.Intersect(Range(Target.Address), Range("A2:D5")) Is Nothing Then '<--- change range as required
    Application.EnableEvents = False
        Sheets(1).Range(Target.Address).Value = Target '<-- change Sheet # as required
    Application.EnableEvents = True
End If
End Sub

Paste in Sheet2 :

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Integer
If Not Application.Intersect(Range(Target.Address), Range("A2:D5")) Is Nothing Then  '<--- change range as required
    Application.EnableEvents = False
        Sheets(2).Range(Target.Address).Value = Target '<-- change Sheet # as required
    Application.EnableEvents = True
End If
End Sub

Possibly...

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rg1 As Range, rg2 As Range

    Set rg1 = Me.Range("a41:a56")
    Set rg2 = rg1.Offset(20, 0)
    Application.EnableEvents = False
    If Not Intersect(Target, rg1) Is Nothing Then Target.Offset(20, 0) = Target
    If Not Intersect(Target, rg2) Is Nothing Then Target.Offset(-20, 0) = Target
    Application.EnableEvents = True
    
End Sub

Sorry for taking so long to reply. Thank you so much. The above code works great. However....

What if I have another range of cells that I want to add to the above cells so that all three update simultaneously, and entry into any of them will update the other two? I tried adapting your code, but it wasn't updating for the new range that was added:

Private Sub Worksheet_Change(ByVal Target As Range)
    

Dim solo41 As Range, solo61 As Range, solo157 As Range

    Set solo41 = Me.Range("a41:a56")
    Set solo61 = solo41.Offset(20, 0)
    Application.EnableEvents = False
    If Not Intersect(Target, solo41) Is Nothing Then Target.Offset(20, 0) = Target
    If Not Intersect(Target, solo61) Is Nothing Then Target.Offset(-20, 0) = Target
    Application.EnableEvents = True
    
    Set solo41 = Me.Range("a41:a56")
    Set solo157 = solo41.Offset(20, 0)
    Application.EnableEvents = False
    If Not Intersect(Target, solo41) Is Nothing Then Target.Offset(116, 0) = Target
    If Not Intersect(Target, solo157) Is Nothing Then Target.Offset(-116, 0) = Target
    Application.EnableEvents = True

End Sub

Thanks. I will do this for all future posts. Thanks for your patience.

Possibly...

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rg1 As Range, rg2 As Range, rg3 As Range

    Set rg1 = Me.Range("a41:a56")
    Set rg2 = rg1.Offset(20, 0)
    Set rg3 = rg1.Offset(116, 0)
    
    Application.EnableEvents = False
    
    If Not Intersect(Target, rg1) Is Nothing Then
        Target.Offset(20, 0) = Target
        Target.Offset(116, 0) = Target
    End If
    
    If Not Intersect(Target, rg2) Is Nothing Then
        Target.Offset(-20, 0) = Target
        Target.Offset(96, 0) = Target
    End If
    
    If Not Intersect(Target, rg3) Is Nothing Then
        Target.Offset(-116, 0) = Target
        Target.Offset(-96, 0) = Target
    End If
    
    Application.EnableEvents = True
End Sub

Nothing really. I just replied to post #5. Didn't see your post.