VBA Program taylors formula

Can you explain the overall objective? You are using the sin function to determine whether the Taylor function has converged to the desired precision. If you are using sin, why not just use sin to calculate the sine?

These declarations are probably not what you intend.

   Dim k, a, b, c, d, s, fakulteta, fakultet As Integer
   Dim i, f As Long
   Dim x, result, taylor As Double

In VBA each variable must explicitly get a type, or it is Variant by default. I think you are assuming that the first line will all be Integer, the second line will all be Long, the third line will all be Double.

   Dim k As Integer, a As Integer, b As Integer, c As Integer, d As Integer, s As Integer, fakulteta As Integer, fakultet As Integer
   Dim i As Long, f As Long
   Dim x As Double, result As Double, taylor As Double

calculation of factorial can be done with a worksheet function

      fakulteta = Application.WorksheetFunction.Fact(i)

and the result should be assigned to a Long. You are getting overflow, which you did not mention in your question. Actually, your post is not a question--not sure what your question is.

Please try this:

Sub sinus_taylor()

   Dim k As Integer, a As Integer, b As Integer, c As Integer, d As Integer, s As Integer
   Dim i As Long, f As Long, fakulteta As Long, fakultet As Long
   Dim x As Double, result As Double, taylor As Double
   'program should read the x value from A2 (radians) and number of decimals from B2 and write the result of sin(x) by taylors formula in C2.
   'i have problem because i dont know how to change do until ... so program would calculate until decimals (k+1) stop changing and after that end loop and round the result on k decimals
   'problem is also overflow
   
   x = Cells(2, 1) 'the x
   k = Cells(2, 2) 'number od decimals
   i = 1
   f = 3
   taylor = 0
   
   Do Until Mid(taylor, (k - 3), 4) = Mid(Sin(x), (k - 3), 4)
   
      If x = 0 Then
         Exit Do
      End If
      'factorial
      fakulteta = Application.WorksheetFunction.Fact(i)
      'factorial
      fakultet = Application.WorksheetFunction.Fact(f)
      
      'taylors formula for sin(x) = ((x ^ 1) / 1!) - ((x ^ 3) / 3!) + ((x ^ 5) / 5!) - ((x ^ 7) / 7!)
      taylor = taylor + (((x ^ i) / (fakulteta)) - ((x ^ f) / (fakultet)))
      
      i = i + 4
      f = f + 4
      
   Loop
   
   result = Round(taylor, k)
   Cells(2, 3) = result 'cell where the result must be written

End Sub

Thank you, but the problem is overflow as you said. Do you know how to fix this. I have to calculate the sin(x) with taylors formula to k decimal places (i must not use sin(x) like i did in macro).

The code I posted does not overflow.

yea thank you a lot. But do you know how would i fix Do until so the program would calculate until k decimal places doesnt change anymore (without comparing to sin(x) like i did).

You monitor the change each time until it falls below the threshold. Also I had to redeclare the factorials as Double to prevent overflow.

So why are you even doing this when you could just use SIN?

Sub sinus_taylor2()

   Dim k As Integer, a As Integer, b As Integer, c As Integer, d As Integer, s As Integer
   Dim i As Long, f As Long, fakulteta As Double, fakultet As Double
   Dim x As Double, result As Double, taylor As Double
   Dim Change As Double
   Dim LastValue As Double
   'program should read the x value from A2 (radians) and number of decimals from B2 and write the result of sin(x) by taylors formula in C2.
   'i have problem because i dont know how to change do until ... so program would calculate until decimals (k+1) stop changing and after that end loop and round the result on k decimals
   'problem is also overflow
   
   x = Cells(2, 1) 'the x
   k = Cells(2, 2) 'number od decimals
   i = 1
   f = 3
   taylor = 0
   Change = 1 ' need a large number for first pass through loop
   
   Do Until Change <= 10 ^ -k  ' Mid(taylor, (k - 3), 4) = Mid(Sin(x), (k - 3), 4)
      If x = 0 Then
         Exit Do
      End If
      'factorial
      fakulteta = Application.WorksheetFunction.Fact(i)
      'factorial
      fakultet = Application.WorksheetFunction.Fact(f)
      
      'taylors formula for sin(x) = ((x ^ 1) / 1!) - ((x ^ 3) / 3!) + ((x ^ 5) / 5!) - ((x ^ 7) / 7!)
      Change = Abs(taylor - (taylor + (((x ^ i) / (fakulteta)) - ((x ^ f) / (fakultet)))))
      
      taylor = taylor + (((x ^ i) / (fakulteta)) - ((x ^ f) / (fakultet)))
      
      i = i + 4
      f = f + 4
      
   Loop
   
   result = Round(taylor, k)
   Cells(2, 3) = result 'cell where the result must be written

End Sub