populate values into textbox on userform based on multiple combobox and two optionbuttons

[ABDELFATTA]

hello
I have this file contains three combobox each other depends on other and I have two optionbutton I would when I select optionbutton (usd) then populate the price in textbox1 from column e for specific item after select from the three combobox and
if i select optionbutton (lyd) then populate the price in textbox1 from column d for specific item after select from the three comboboxes
note: the file contains code if this is not suitable I accept alternative
thanks

[LeoTaxi]

First select option1 or 2 then select choose from combo 1 with this code

Private Sub ComboBox1_Click()
Dim rng As Range, col As Integer
If OptionButton1 Then
    col = 3
ElseIf OptionButton2 Then
    col = 4
Else
    MsgBox "First select LYD or USD"
    ComboBox1.ListIndex = -1
    Exit Sub
End If
With Sheets("Brand").Range("A:A")
    Set rng = .Find(ComboBox1.List(ComboBox1.ListIndex, 0), _
        lookat:=xlWhole, _
        searchorder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=False)
        If Not rng Is Nothing Then
            ComboBox2.AddItem Sheets("Brand").Range("B" & rng.Row).Value
            ComboBox3.AddItem Sheets("Brand").Range("C" & rng.Row).Value
            TextBox1 = Sheets("Brand").Range("A" & rng.Row).Offset(, col).Value
        End If
End With
ComboBox2.ListIndex = 0
ComboBox3.ListIndex = 0
End Sub

Kind regards
Leo

[ABDELFATTA]

perfect leo jut i want a little amending if is possible when select option 1 and select item from combobox1 is ok but when I select option2 to the same item nothing change I have to change item to see change

[jindon]

Replace whole code in UserForm code module with the following code.

Option Explicit
Private dic As Object

Private Sub UserForm_Initialize()
    Dim a, i As Long, ii As Long
    Set dic = CreateObject("Scripting.Dictionary")
    With Sheets("brand").Cells(1).CurrentRegion
        a = .Parent.Evaluate(.Address & "&""""")
    End With
    For i = 2 To UBound(a, 1)
        If Not dic.exists(a(i, 1)) Then
            Set dic(a(i, 1)) = CreateObject("Scripting.Dictionary")
        End If
        If Not dic(a(i, 1)).exists(a(i, 2)) Then
            Set dic(a(i, 1))(a(i, 2)) = CreateObject("Scripting.Dictionary")
        End If
        dic(a(i, 1))(a(i, 2))(a(i, 3)) = Array(a(i, 4), a(i, 5))
    Next
    Me.ComboBox1.List = dic.keys
End Sub

Private Sub ComboBox1_Click()
   Me.ComboBox2.Clear
   Me.ComboBox3.Clear
   Me.ComboBox2.List = dic(Me.ComboBox1.Value).keys
   GetPrice
End Sub

Private Sub ComboBox2_Click()
   Me.ComboBox3.Clear
   Me.ComboBox3.List = dic(Me.ComboBox1.Value)(Me.ComboBox2.Value).keys
   GetPrice
End Sub

Private Sub ComboBox3_Click()
   GetPrice
End Sub

Private Sub TextBox1_AFTERUPDATE()
    With Me.TextBox1
        If IsNumeric(.Value) Then .Value = Format(.Value, "$#,##0.00")
    End With
End Sub

Private Sub OptionButton1_Click()
    GetPrice
End Sub

Private Sub OptionButton2_Click()
    GetPrice
End Sub

Private Sub GetPrice()
    Dim i As Long, myCol As Long
    Me.TextBox1 = ""
    For i = 1 To 3
        If Me("combobox" & i).ListIndex = -1 Then Exit Sub
    Next
    If Not dic.exists(Me.ComboBox1.Value) Then Exit Sub
    If Not dic(Me.ComboBox1.Value).exists(Me.ComboBox2.Value) Then Exit Sub
    If Not dic(Me.ComboBox1.Value)(Me.ComboBox2.Value).exists(Me.ComboBox3.Value) Then Exit Sub
    For i = 1 To 2
        If Me("optionbutton" & i) Then Exit For
    Next
    If i < 3 Then Me.TextBox1 = Format$(dic(Me.ComboBox1.Value)(Me.ComboBox2.Value)(Me.ComboBox3.Value)(i - 1), "$#,##0.00")
End Sub

[ABDELFATTA]

great achievement ! many thanks mr.Jindon ​​​​