Getting: could not get List property. Invalid argument error

"A VBA ListBox will not display more than 10 columns of data unless you link the ListBox to Range using the "RowSource" property."

Private Sub lstTools_Click()
    
    With lstTools
        txtDept = .List(.ListIndex, 0)
        txtTools = .List(.ListIndex, 1)
        txtStatus = .List(.ListIndex, 2)
        txtDateRet = .List(.ListIndex, 3)
        txtRetBy = .List(.ListIndex, 4)
        txtActive = .List(.ListIndex, 5)
        txtMT = .List(.ListIndex, 6)
        txtInspBy = .List(.ListIndex, 7)
        txtVerBy = .List(.ListIndex, 8)
        txtDateInsp = .List(.ListIndex, 9)
        txtDateVer = .List(.ListIndex, 10)
        txtDamaged = .List(.ListIndex, 11)
        txtComments = .List(.ListIndex, 12)
    End With
    
End Sub

Private Sub UserForm_Initialize()
    Dim mysheet As Worksheet, lastrow As Long
    
    Set mysheet = ThisWorkbook.Sheets("Tracker")
    
    lastrow = mysheet.Cells(Rows.Count, 1).End(xlUp).Row
    
    Me.lstTools.ColumnCount = 13
    Me.lstTools.ColumnWidths = "50;50;30;60;50;30;50;50;50;50;50;50;200"
    
    Me.lstTools.RowSource = mysheet.Range("A2:M" & lastrow).Address(External:=True)
    
End Sub

You can also load more than 11 columns by loading the List from an array.

Private Sub UserForm_Initialize()
    Dim mysheet As Worksheet
    Dim listData As Variant
    
    Set mysheet = ThisWorkbook.Sheets("Tracker")
    
    lastrow = mysheet.Cells(Rows.Count, 1).End(xlUp).Row
    'For Each cell In [cboList]
    '  Me.cboStatus.AddItem cell
    'Next cell
    
    listData = mysheet.Cells(2, 1).Resize(lastrow - 2 + 1, 13)
    Me.lstTools.ColumnCount = 13
    Me.lstTools.List = listData
    
    With Me
        Width = Application.Width * 0.5
        Height = Application.Height * 0.6
    End With
    'For Each x In [TList]
    '    Me.cmbTools.AddItem x
    'Next x

End Sub

Or...

Private Sub UserForm_Initialize()
Dim Arr
Arr = Sheets("Tracker").ListObjects(1).DataBodyRange.Value
With Me.lstTools
    .ColumnCount = 13
    .ColumnWidths = "40;40;40;40;40;40;40;40;40;40;40;40;40"
    .List = Arr
End With
End Sub