USE ALL CODES in 1 code

I'd take such measures to make it quicker
in AllSheets

application.screenupdating = false ' at the beginning
'...
application.screenupdating = true ' at the end

Swithing off automatic recalculation and calling

activesheet.calculate

only after

Range("m2:m" & LR)

is filled with formula, then after

Range("r2:r" & clr)

is filled with formula
If you don't need formulas in M and R columns I'd convert (after recalculation) these columns formulas -> to values, like:

Range("m2:m" & LR) = "=IF(L2-E2=L2 ,"""",IF(L2-E2=-E2,"""",L2-E2))"
Activesheet.calculate
Range("m2:m" & LR).value = Range("m2:m" & LR).value

I'd not use

ActiveWorkbook.Save

after each graph is prepared (it's 800 large workbook saving actions!)

and as for errors searching and replacing - if you could allow all errors (not only #DIV/0!) to be replaced with "" then

Sub ReplaceDivError()

Dim r As Range
Dim lr As Integer

lr = Cells(Rows.Count, "r").End(xlUp).Row
Set r = Range("r2:r" & lr).SpecialCells(xlCellTypeFormulas, 16) 'this could be skipped if column R was transformed to values before
if not r is nothing then 'and this
  r.value - "" 'and this
else 'and this
  Set r = Range("r2:r" & lr).SpecialCells(xlCellTypeConstants, 16)
  if not r is nothing then r.value - ""
end if ' and this

End Sub

PS. Just putting all actions into one sub (which is perfectly possible) will save you no noticeable time amount. But the proposed ammendments could save a lot. Of courrse 800 sheets (with 800 graphs!) is still very large file and some time will be needed to process it.

800 sheets - 4 Hours...
As per Kaper suggestions...Down to 8 seconds...
I don't see the need for Error delete code...Perhaps formula need to be adjusted to ensure no errors in formula...
can only see once a sample file is uploaded containing such errors...

Option Explicit

Sub AllSheets()
Dim ws As Worksheet, ch As Object, lr As Long, clr As Long
Dim ydata As Range, xdata As Range, cell As Range
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For Each ws In ThisWorkbook.Worksheets
    With ws
        ' ! Formula Code...............................................
        lr = .Cells(.Rows.Count, 1).End(xlUp).Row
        .Range(.Cells(1, 2), .Cells(lr, 2)).AdvancedFilter xlFilterCopy, , .Range("Q1"), True
        .Range("M2:M" & lr).formula = "=IF(L2-E2=L2 ,"""",IF(L2-E2=-E2,"""",L2-E2))"
        clr = .Cells(Rows.Count, 17).End(xlUp).Row
        .Range("R1") = "Average"
        .Range("R2:R" & clr).formula = "=AVERAGEIFS($M$2:$M$" & lr & ",$B$2:$B$" & lr & ",Q2)"
        
        ' ! Chart Code......................................................
        Set cell = .Range("N20") ' ! Start Position of Chart
        Set ch = .ChartObjects.Add(Left:=cell.Left, Width:=400, Top:=cell.Top, Height:=250)
        lr = .Cells(.Rows.Count, 17).End(xlUp).Row
        Set xdata = .Range("Q2:Q" & lr): Set ydata = .Range("R2:R" & lr)
        With ch.Chart
            .ChartType = xlXYScatterLines
            .SeriesCollection.NewSeries
            With .SeriesCollection(1): .XValues = xdata: .Values = ydata: End With
            With .ChartArea.Border: .Color = vbRed: .Weight = 3.25: End With
          End With
    End With
Next ws
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

if you want to clear errors just change formula...

 .Range("R2:R" & clr).Formula = "=IFERROR(AVERAGEIFS($M$2:$M$" & lr & ",$B$2:$B$" & lr & ",Q2),"""")"