VBA to add leading zero.

I am trying to run VBA code to add a leading zero so that the figures are 2 in length;
e.g. 1 becomes 01

I have looked around and found some code, it doesn't error but it doesn't add a leading zero when run.

Sub Leading_Zero()
Dim LZero As String
Application.ScreenUpdating = False

LZero = Empty

Worksheets(1).Columns("A").NumberFormat = "@"
Range("A1").Select
If Len(Cell) < 2 Then
        Cell = WorksheetFunction.Rept("0", 1 - Len(Cell)) & Cell
End If

Do Until LZero = "End"
    ActiveCell.Offset(7, 0).Activate
    If ActiveCell.Value <> "" Then
        If Len(Cell) < 2 Then
            Cell = WorksheetFunction.Rept("0", 1 - Len(Cell)) & Cell
        End If
    ElseIf ActiveCell.Value = "" Then
        LZero = "End"
    End If
Loop

Application.ScreenUpdating = True
Range("A1").Select
End Sub

I have attached an example sheet.

https://excelchamps.com/blog/leading-zeros/

Look at #5

Here is another macro (no loops) that should also work...

Sub Vulnerability_Review_Sort()
  With Range("A1", Cells(Rows.Count, "A").End(xlUp))
    .SpecialCells(xlConstants).NumberFormat = "@"
    .Value = Evaluate(Replace("IF(LEN(@),TEXT(@,""00""),"""")", "@", .Address))
  End With
End Sub

Actually, in thinking about it some more... given the OP's layout, we only need to examine up to Row 57 (that is, the cells containing either blanks or the first 9 numbers) since after that, all number cells will consist of two digits (assuming the OP's numbering stops at 99 maximum). Given that, this macro should also work...

Sub Vulnerability_Review_Sort()
  [A1:A57].NumberFormat = "@"
  [A1:A57] = [IF(LEN(A1:A57),TEXT(A1:A57,"00"),"")]
End Sub

Thank you all for your help, I have gone with Rick's last submission with a little edit :-D

Worksheets(1).Columns("A").NumberFormat = "@"
[A1:A57] = [IF(LEN(A1:A57),TEXT(A1:A57,"00"),"")]