Add data to the next available row in an Excel table

Hi there,

I am looking to add data from one sheet to another using vba code.

Here's what I have so far:

Sub Test()

Sheets("Correspondence Log").Select

ProjectComponent = Range("B2").Value

Originator = Range("C2").Value

DocumentType = Range("D2").Value

Discipline = Range("E2").Value

Title = Range("F2").Value



Sheets("Database").Select

Set ws = ActiveSheet

Dim newrow As ListRow

Set newrow = ws.ListObjects("frmFileListDS").ListRows.Add


With nextrow

    .Range(1) = ProjectComponent
    .Range(2) = Originator
    .Range(3) = DocumentType
    .Range(4) = Discipline
    .Range(7) = Title
    

End With


End Sub

This code works to add code to the end of an excel table but how can I add this data to the next available row?

Any help would be gratly appreciated!

Administrative Note:

Welcome to the forum.

We would very much like to help you with your query, however you need to include code tags around your code.

Please take a moment to add the tags. Posting code between tags makes your code much easier to read and copy for testing, and it also maintains VBA formatting.

Please see Forum Rule #2 about code tags and adjust accordingly. Click on Edit to open your post, then highlight your code and click the # icon at the top of your post window. More information about these and other tags can be found here

I did it for you this time. Please read forum rules. Thanks

Originally Posted by SukeL

This code works to add code to the end of an excel table but how can I add this data to the next available row?

Do you mean the table may have empty rows, and you want to fill the next available empty row?

Sub Test()
    
    Dim wsCL    As Worksheet
    Dim tbl     As ListObject
    Dim NextRow As Range
    
    Set wsCL = Sheets("Correspondence Log")
    Set tbl = Sheets("Database").ListObjects("frmFileListDS")
    
    If tbl.Range(tbl.Range.Rows.Count, 1) <> Empty Then 'If the last row is not blank
        'Add a new row
        Set NextRow = tbl.ListRows.Add.Range
    Else
        'Find the next avalable blank row
        Set NextRow = tbl.Range(tbl.Range.Rows.Count, 1).End(xlUp).Offset(1)
    End If
    
    NextRow.Resize(1, 4).Value = wsCL.Range("B2:E2").Value 'ProjectComponent,Originator,DocumentType,Discipline
    NextRow(1, 7).Value = wsCL.Range("F2").Value 'Title
    
End Sub

You're welcome I guess? I'll just assume the first code worked.

This will copy the "automatically flows in" values from columns G and H of the table Row where data was entered and then pastes to the next empty row of the Correspondence Log columns B and C.

Sub Test()
    
    Dim wsCL    As Worksheet
    Dim tbl     As ListObject
    Dim NextRow As Range
    
    Set wsCL = Sheets("Correspondence Log")
    Set tbl = Sheets("Database").ListObjects(1) '("frmFileListDS")
    
    If tbl.Range(tbl.Range.Rows.Count, 1) <> Empty Then 'If the last row is not blank
        'Add a new row
        Set NextRow = tbl.ListRows.Add.Range
    Else
        'Find the next avalable blank row
        Set NextRow = tbl.Range(tbl.Range.Rows.Count, 1).End(xlUp).Offset(1)
    End If
    
    NextRow.Resize(1, 4).Value = wsCL.Range("B2:E2").Value 'ProjectComponent,Originator,DocumentType,Discipline
    NextRow(1, 7).Value = wsCL.Range("F2").Value 'Title
    
    wsCL.Range("B" & Rows.Count).End(xlUp).Offset(1).Resize(1, 2).Value = _
        NextRow.EntireRow.Range("G1:H1").Value
    
End Sub