Move Screen to mimic active sheet

Hi Guys,

I have a spreadsheet, where I have identical tabs (same column widths, same titles on columns, etc), the only difference is a few values. I want to be able to flick between the sheet1 and sheet2 quickly and be in the same viewing location when I go to the other sheet.

eg: What I need is when I move from sheet1 to sheet2, for the view to be the same.

If I'm viewing sheet1 and move the screen to show ColumnG to ColumnZ, and then click on sheet2, sheet2 will show whatever sheet2 last showed. I need sheet2 to also show ColumnG to ColumnZ when I click on it; so that I can quickly determine what is different between the two sheets.

I hope that makes sense.
Thanks guys,

Put this in the ThisWorkbook code module. Change the sheet names to suit.

Dim ScrRow As Long, ScrCol As Long, bIgnor As Boolean

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
     Dim sh1 As Worksheet, sh2 As Worksheet
     If Not bIgnor Then
        Set sh1 = Sheets("Sheet1")
        Set sh2 = Sheets("Sheet2")
        bIgnor = True
        Select Case Sh.Name
            Case sh1.Name, sh2.Name
                If Sh Is sh1 Then sh2.Activate Else sh1.Activate
                ScrRow = ActiveWindow.ScrollRow
                ScrCol = ActiveWindow.ScrollColumn
                Sh.Activate
                ActiveWindow.ScrollRow = ScrRow
                ActiveWindow.ScrollColumn = ScrCol
        End Select
        bIgnor = False
     End If
End Sub

Hi AlphaFrog,

what you have given is a good start, I'm working on trying to fit your code.

I'm wondering if there is a way to get "the sheet you just left" (eg, similar to "activesheet" but instead something like "sheet that was active before current activesheet").
I have 5 sheets all similar (and then other tabs that are not similar) and I want whatever sheet's view (if its 1 of the 5 similar ones) to then be 'pushed' onto the other 4 sheets, just before you switch sheet.

Dim ScrRow As Long, ScrCol As Long, bIgnor As Boolean, shPrevious As Worksheet

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
     Dim sh1 As Worksheet, sh2 As Worksheet
     If Not bIgnor Then
        bIgnor = True
        If Not shPrevious Is Nothing Then
            Select Case Sh.CodeName
                Case "Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet5"
                    shPrevious.Activate
                    ScrRow = ActiveWindow.ScrollRow
                    ScrCol = ActiveWindow.ScrollColumn
                    Sh.Activate
                    ActiveWindow.ScrollRow = ScrRow
                    ActiveWindow.ScrollColumn = ScrCol
            End Select
        End If
        bIgnor = False
     End If
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    Select Case Sh.CodeName
        Case "Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet5"
            Set shPrevious = Sh
    End Select
End Sub

*Removing Post because not needed*

Hi AlphaFrog,

OMG, that code is so awesome!
Seriously, you're awesome!

However, I have another layer of problem:
As you can guess:
"69%C 31%P",
"63%C 37%P",
"56%C 44%P",
"50%C 50%P",
"44%C 56%P" need to look the same.

The same spreadsheet also has:
"Long forecast -70% 30%P",
"Long forecast -50% 50%P",
"Long forecast -0% 100%P" need to look the same as each other too. (but are unrelated to "XX%C XX%P")

The same spreadsheet also has:
"Test Num 01"
"Test Num 02"
"Test Num 03" need to look the same as each other too. (but are unrelated to "XX%C XX%P" and unrelated to "Long forecast - XX%C XX%P")

I'm hoping that if you help me with this code, I'd be able to expand it to create N different "groups" of tabs within a workbook.
Please and thank you!

You're welcome.

I have no idea what the rest means. Sounds like a whole new question. It would be best to start a new thread.