How To do data validation for matching entries between 2 cells based on input in 3rd cell

I would like to apply data validation to cell K3 based on A3

The value of K3 only comes up after a correct numerical code is entered in K4 (based on the formula in K3 referencing Source! )

basically I want the file to reject the entry in K4 if the resulting value on K3 does not match A3

so as to prevent a different user signing off on a time log that is not tied to their ID

as it currently set up any one can sign off any time log entry... (resulting in the signee being different from A3) the goal is so that only the person selected in A3 can successfully enter a code in K4 so that the K3=A3

In a copy of your file, delete all the formulas in column K. Copy and paste this macro into the worksheet code module. Do the following: right click the tab name for your "Time Log" sheet and click 'View Code'. Paste the macro into the empty code window that opens up. Close the code window to return to your sheet. Make an entry in K4 and press the RETURN key.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("K:K")) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Dim fnd As Range
    If Target.Row Mod 2 = 0 Then
        Set fnd = Sheets("Source").Range("C:C").Find(Target.Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not fnd Is Nothing Then
            If fnd.Offset(, -1) <> Target.Offset(-1, -10) Then
                Target.ClearContents
                MsgBox ("Only " & Target.Offset(-1, -10) & " can enter a code in cell " & Target.Address(0, 0) & ".")
            Else
                Target.Offset(-1) = fnd.Offset(, -1)
            End If
        End If
    End If
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

Is there a way to make it work with the cell K3 being protected (before or after?) so that someone can't just delete the generated value in K3 and i suppose K4 would need to lock after a successful entry as well to prevent any alterations?

Start by unlocking all the cells in the sheet "Time Log". Then replace the previous macro with the one below:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("K:K")) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    ActiveSheet.Unprotect Password:="MyPassword"
    Dim fnd As Range
    If Target.Row Mod 2 = 0 Then
        Set fnd = Sheets("Source").Range("C:C").Find(Target.Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not fnd Is Nothing Then
            If fnd.Offset(, -1) <> Target.Offset(-1, -10) Then
                Target.ClearContents
                MsgBox ("Only " & Target.Offset(-1, -10) & " can enter a code in cell " & Target.Address(0, 0) & ".")
            Else
                Target.Offset(-1) = fnd.Offset(, -1)
                Target.Offset(-1).Resize(2).Locked = True
            End If
        End If
    End If
    ActiveSheet.Protect Password:="MyPassword"
    ActiveSheet.EnableSelection = xlUnlockedCells
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

In order to lock the cells, the sheet must be protected. Change the password in the code (in red) to a password of your choosing.

thank you for this, the code works just perfectly, If I can please ask for you assistance once more.

I just noticed there is a flaw in the excel sheet. How to make it so that A3:J3 ( and subsequent rows A5:J5 etc) is locked after is L5 (MOD sign) signed to complete the data entry for that employee. Ideally L4 will lock as well after entry

Try:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("K:L")) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    ActiveSheet.Unprotect Password:="MyPassword"
    Dim fnd As Range
    Select Case Target.Column
        Case Is = 11
            If Target.Row Mod 2 = 0 Then
                Set fnd = Sheets("Source").Range("C:C").Find(Target.Value, LookIn:=xlValues, lookat:=xlWhole)
                If Not fnd Is Nothing Then
                    If fnd.Offset(, -1) <> Target.Offset(-1, -10) Then
                        Target.ClearContents
                        MsgBox ("Only " & Target.Offset(-1, -10) & " can enter a code in cell " & Target.Address(0, 0) & ".")
                    Else
                        Target.Offset(-1) = fnd.Offset(, -1)
                        Target.Offset(-1).Resize(2).Locked = True
                    End If
                End If
            End If
        Case Is = 12
            If Target.Row Mod 2 = 1 Then
                Range("A" & Target.Row).Resize(, 12).Locked = True
            End If
    End Select
    ActiveSheet.Protect Password:="MyPassword"
    ActiveSheet.EnableSelection = xlUnlockedCells
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub