mandatory cells

Hello to all.
This macro:

Option Explicit


Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim cella As Range
Application.EnableEvents = False


Set cella = Cells(Target.Row, 1) '<<< cella singola

With cella
If .Value = "" Then

'MsgBox "Devi inserire una data nella cella  A" & Target.Row & " ", vbCritical, "Errore!"
MsgBox "You must enter a date in cell A" & Target.Row & " ", vbCritical, "Errore!"

End If

End With


Application.EnableEvents = True
End Sub

you must enter a date in cell A mandatory
Now I added mandatory too column B / C / D but the warning appears 3 times, but it should only appear in the selected cell.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim cella As Range
Application.EnableEvents = False

'Set cella = Range("A3") '<<< cella singola
'Set cella = Cells(Target.Row, Target.Column) '<<< colonna

Set cella = Cells(Target.Row, 1) '<<< cella singola

With cella
If .Value = "" Then

'MsgBox "Devi inserire una data nella cella  A" & Target.Row & " ", vbCritical, "Errore!"
MsgBox "You must enter a date in cell A" & Target.Row & " ", vbCritical, "Errore!"

End If

End With


Set cella = Cells(Target.Row, 2) '<<< cella singola

With cella
If .Value = "" Then

MsgBox "Devi inserire il reparto nella cella  B" & Target.Row & " ", vbCritical, "Errore!"

End If

End With



Set cella = Cells(Target.Row, 3) '<<< cella singola

With cella
If .Value = "" Then

MsgBox "Devi inserire l'operatore nella cella  C" & Target.Row & " ", vbCritical, "Errore!"

End If

End With



Set cella = Cells(Target.Row, 4) '<<< cella singola

With cella
If .Value = "" Then

MsgBox "Devi inserire il tempo nella cella  D" & Target.Row & " ", vbCritical, "Errore!"

End If

End With



Application.EnableEvents = True
End Sub

you can edit?
xam

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim cella As Range
Application.EnableEvents = False

'Set cella = Range("A3") '<<< cella singola
'Set cella = Cells(Target.Row, Target.Column) '<<< colonna

Set cella = Cells(Target.Row, 1) '<<< cella singola

With cella
If .Value = "" Then

'MsgBox "Devi inserire una data nella cella A" & Target.Row & " ", vbCritical, "Errore!"
MsgBox "You must enter a date in cell A" & Target.Row & " ", vbCritical, "Errore!"

End If

End With
' ...... etc

End Sub

Why not just exit the sub after the first failed test?

e.g.

With cella
If .Value = "" Then

'MsgBox "Devi inserire una data nella cella  A" & Target.Row & " ", vbCritical, "Errore!"
MsgBox "You must enter a date in cell A" & Target.Row & " ", vbCritical, "Errore!"
cella.select
exit sub

End If

HTH
Tim


EDIT
Remember to re-enable events!

 
Cella.Select
Application.EnableEvents = TRUE
Exit Sub

For starters. This one will only give 1 messagebox when data is missing in one of the columns.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    If Application.CountA(Cells(Target.Row, 1).Resize(, 4)) <> 4 Then MsgBox "Missing data on Row " & Target.Row

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim i As Long
    For i = 1 To 4
        If Cells(Target.Row, i) = vbNullString Then
            Application.EnableEvents = False
            MsgBox "Devi inserire il reparto nella cella " & Chr(i + 64) & Target.Row & " ", vbCritical, "Errore!"
            Application.Goto Cells(Target.Row, i)
            Application.EnableEvents = True
            Exit Sub
        End If
    Next
End Sub

Haha! Bakerman2's solution is far more elegant (as usual), why not tweak it a bit to make it flexible:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim i As Long
    For i = 1 To Target.Cells.count
        If Cells(Target.Row, i) = vbNullString Then
            Application.EnableEvents = False
            MsgBox "Devi inserire il reparto nella cella " & Chr(i + 64) & Target.Row & " ", vbCritical, "Errore!"
            Application.Goto Cells(Target.Row, i)
            Application.EnableEvents = True
            Exit Sub
        End If
    Next
End Sub

Tim

Didn't notice there was always a different message.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim i As Long, myarr
    myarr = Array(" una data ", " il reparto ", " l'operatore ", " il tempo ")
    For i = 1 To 4
        If Cells(Target.Row, i) = vbNullString Then
            Application.EnableEvents = False
            MsgBox "Devi inserire" & myarr(i - 1) & "nella cella " & Chr(i + 64) & Target.Row & " ", vbCritical, "Errore!"
            Application.Goto Cells(Target.Row, i)
            Application.EnableEvents = True
            Exit Sub
        End If
    Next
End Sub

Post an example file with the new layout.

Try this then.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim i As Long, myarr, x
    
    If Target.Row < 3 Then Exit Sub
    
    If Target.Column <> 3 And Target.Column <> 4 Then
    
        myarr = Array(" una data ", " il reparto ", " l'operatore ", " il tempo ")
        
        x = Split("1,2,5,6", ",")
        
        For i = 0 To 3
            If Cells(Target.Row, CInt(x(i))) = vbNullString Then
                Application.EnableEvents = False
                MsgBox "Devi inserire" & myarr(i) & "nella cella " & Chr(IIf(i < 2, i, i + 2) + 65) & Target.Row & " ", vbCritical, "Errore!"
                Application.Goto Cells(Target.Row, IIf(i < 2, i + 1, i + 3))
                Application.EnableEvents = True
                Exit For
            End If
        Next
    End If
End Sub