VBA Procedure too large error

You need to refactor the code. Try something like this:

Sub GetTable()

   Dim ieApp As InternetExplorer
   Dim url As String
   Dim myPoints As String

   'create a new instance of ie
   Set ieApp = New InternetExplorer

   'you don’t need this, but it’s good for debugging
   ieApp.Visible = True

   'assume we’re not logged in and just go directly to the login page
   ieApp.Navigate "https://icms.indianrail.gov.in/reports/"
   Do While ieApp.Busy: DoEvents: Loop
   Do Until ieApp.ReadyState = READYSTATE_COMPLETE: DoEvents: Loop

   Set ieDoc = ieApp.Document

   'fill in the login form – View Source from your browser to get the control names
   With ieDoc.forms(0)
      .UserId.Value = "abcdefg"
      .Password.Value = "123456"
      .submit
   End With
   Do While ieApp.Busy: DoEvents: Loop
   Do Until ieApp.ReadyState = READYSTATE_COMPLETE: DoEvents: Loop

   Dim n As Long
   For n = 2 To 600
      Get_IE_Output ieApp, Sheet1.Cells(n, "B").Value, Sheet1.Cells(n, "D")
   Next n
   ieApp.Quit
End Sub
Sub Get_IE_Output(ieApp As InternetExplorer, trainNo, outputRange As Range)
'now that we’re in, go to the page we want
   ieApp.Navigate "https://icms.indianrail.gov.in/reports/ReportServlet?reportAction=Utility&reportType=LocoCurrStatus&subAction=main"
   Do While ieApp.Busy: DoEvents: Loop
   Do Until ieApp.ReadyState = READYSTATE_COMPLETE: DoEvents: Loop
   Dim ieDoc As Object

   'get the table based on the table’s id
   Set ieDoc = ieApp.Document
   With ieDoc.forms(0)
      .trainNo.Value = trainNo
      .startDate.Value = Format(Date - 1, "dd-mmm-yyyy")
      .submit
   End With
   Do While ieApp.Busy: DoEvents: Loop
   Do Until ieApp.ReadyState = READYSTATE_COMPLETE: DoEvents: Loop

   Set ieDoc = ieApp.Document
   Dim ieTable As Object
   Set ieTable = ieDoc.all.Item("TABLE_6")

   'copy the tables html to the clipboard and paste to teh sheet
   If Not ieTable Is Nothing Then
      Dim clip As DataObject
      Set clip = New DataObject
      clip.SetText "" & ieTable.outerHTML & ""
      clip.PutInClipboard
      With outputRange.Worksheet
         .Select
         outputRange.Select
         .PasteSpecial "Unicode Text"
      End With
   End If

End Sub