comparing values in named ranges

Hello I have 2 named ranges I want the values in named range 2 to be compared against the values in named range 1 and if they match change the background colour of that cell or highlight the cell in named range 1.

I have tried various versions of this code below, but have run into errors

Sub CheckNumbers()

    Dim rng1 As Range, rng2 As Range, i As Long, j As Long
    Dim rw As Range
   
    With Sheets("Play")
        Set rng1 = .Range("Namedrange1")
        Set rng2 = .Range("Namedrange2")
       
        'For j = 1 To Sheets("Sheet3").Range("C" & Rows.Count).End(xlUp).Row
         For Each rw In Sheets("play").Range("Namedrange1")
            
            If StrComp(Trim(rng1.Value), Trim(rng2.Value), vbDatabaseCompare) = 0 Then
                rng1.Interior.Color = RGB(255, 255, 0)
            End If
            Set rng2 = Nothing
        
        Set rng1 = Nothing
        
  Next rw
   End With
End Sub

Named range 1 = C3:G34
Named range 2 = N6:R6 1 row

Thank you for any help provided

Hi UltimateNeo,

hope this helps

Sub CheckNumbers()

   Dim rng1 As Range, rng2 As Range
   Dim cel1 As Range, cel2 As Range
   
   With Sheets("Play")
      Set rng1 = .Range("Namedrange1")
      Set rng2 = .Range("Namedrange2")
      
      For Each cel1 In Sheets("play").Range("Namedrange1")
         For Each cel2 In Sheets("play").Range("Namedrange2")
            If StrComp(Trim(cel1.Value), Trim(cel2.Value), vbTextCompare) = 0 Then
               cel1.Interior.Color = RGB(255, 255, 0)
            End If
         Next cel2
      Next cel1
      Set rng2 = Nothing
      Set rng1 = Nothing
   End With
   
End Sub

Grtz

Try such combination:

    'Color   Red  Green Blue
    '=======================
    'Black   0    0     0
    'Blue    0    0     255
    'Green   0    255   0
    'Cyan    0    255   255
    'Red     255  0     0
    'Magenta 255  0     255
    'Yellow  255  255   0
    'White   255  255   255

Sub CheckKangarooNumbers()
    Dim i%, x%, y%, z%, rng1, rng2
    
    With Sheets("Play")
        rng2 = .Range("Namedrange2").Value
        With .Range("Namedrange1")
            rng1 = .Value
            .ClearFormats
            For i = 1 To UBound(rng2, 2)
                x = x + 25
                y = y + 50
                z = z + 5
                Application.ReplaceFormat.Interior.Color = RGB(100 + x, 50 + y, 10 + z)
                .Replace What:=rng2(1, i), Replacement:=rng2(1, i), LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=True
            Next
        End With
    End With
End Sub