Have Autorun Macros but can we stop them running at one particular interval

If the fact that the application ontime is still active, you could add an IF statement that checks if the VT value is a Friday and the VT time falls between 8:55 AM and 10:15 AM
You'll have to play around with that, it's just an idea that popped up

Private Sub Display()
    If Rg Is Nothing Or IsEmpty(VA) Then Exit Sub
    ActiveWindow.ScrollRow = Rg.Row
    Set Rg = Rg.End(xlDown):  If IsEmpty(Rg) Then Set Rg = [B3]
    If Weekday(Date) = vbFriday And Time >= TimeValue("8:55 AM") And Time < TimeValue("10:15 AM") Then
        VT = Date + TimeValue("10:15 AM")
    Else
        VT = Now + VA
    End If
    Application.OnTime VT, "ThisWorkbook.Display"
End Sub

Hi There,

I'm reopening this thread not because of my original questions which I posted earlier (those 2 things have been resolved) but I have new ask and this one is on the similar lines as my earlier. Also, this could be a simple one and that's the reason I don't want to open up a new thread. Hope I'm not violating any procedures here

Ask:
I wanted a macro to autorun on a particular day and at particular time ---- Every Friday at 8:47 AM. Below is the codes (1) and (2) I have written based on the similar on what was given to me earlier. Not sure what is wrong but this is not working. Can you please look into it and correct this. Thanks in advance!!

Code-1

Sub RunOneTimeOnFridayMorn()

    Call Workbook_Open

        If Weekday(Date) = vbFriday And Time = TimeValue("08:47 AM") Then
            LapTime2 = Date + TimeValue("08:47 AM")
        End If

            Application.OnTime LapTime2, "RunOneTimeOnFridayMorn"
End Sub

Code 2

Sub RunOneTimeOnFridayMorn()

    Call Workbook_Open

        If Weekday(Date) = vbFriday And Time = TimeValue("08:47 AM") Then
            LapTime2 = Date + TimeValue("08:47 AM")
            Application.OnTime LapTime2, "RunOneTimeOnFridayMorn"
        End If
End Sub

If you want it to run on a friday at a specific time, just set that in a variable and set the application ontime to that date and time and forget about checking if then else.

The If then else was good for your first question because you wanted it NOT to run between two values.

What's in Workbook_Open ???
What's the name of the macro you want to run on friday morning?

My idea:

Place the code below in a Module
The Red line of code is the topmost outside the subs

Global LapTime2     As Date

Public Sub setFridayMorningRun()
Dim tDays   As Integer
tDays = Choose(Weekday(Date), 5, 4, 3, 2, 1, 0, 6)
If tDays = 0 Then
    If Time > TimeValue("08:47 AM") Then tDays = tDays + 7
End If
LapTime2 = (Date + tDays) + TimeSerial(8, 47, 0)
Application.OnTime LapTime2, "RunOneTimeOnFridayMorn"
End Sub

Public Sub stopFridayMorningRun()
On Error Resume Next
Application.OnTime Earliesttime:=LapTime2, Process:="RunOneTimeOnFridayMorn", Schedule:=Flase
Err.Clear
On Error GoTo 0
End Sub

Public Sub RunOneTimeOnFridayMorn()
' here the code you want to run on friday morning



' when it completes you run setFridayMorningRun again
setFridayMorningRun
End Sub

In the Workbook_Open event

Private Sub Workbook_Open()
setFridayMorningRun
End Sub

So every time the workbook is opened the macro is set to run on a friday at 8 47 AM

I also suggest you place this in the

Private Sub Workbook_BeforeClose(Cancel As Boolean)
stopFridayMorningRun
End Sub

Another way to calc the next Friday

Public Sub setFridayMorningRun()
    LapTime2 = Date + 8 - Weekday(Date, vbFriday) + TimeValue("08:47 AM")
    If LapTime2 - Now > 7 Then LapTime2 = LapTime2 - 7
    Application.OnTime LapTime2, "RunOneTimeOnFridayMorn"
End Sub

@AlphaFrog: true,much simpler,