Quickly create folders and subfolders with vba

**amartin575** · 10-17-2019, 04:17 PM

Hello,

I have the attached file and code used to create folders and subfolders on the fly. It usually performs the task rather quickly however I have a lot of folders and subs to create now and the file is taking a long time to complete. Any recommendations on altering the code below to make it run faster?

Sub CreateFolderStructure()
    Dim objRow As Range, objCell As Range, strFolders As String

    For Each objRow In ActiveSheet.UsedRange.Rows
        strFolders = "C:\Users\Anthony.Martin\Documents\0-Test"
        For Each objCell In objRow.Cells
            strFolders = strFolders & "\" & objCell
        Next
        Shell ("cmd /c md " & Chr(34) & strFolders & Chr(34))
    Next
End Sub

**karedog** · 10-18-2019, 12:36 AM

Maybe :

Option Explicit
#If Win64 Then
    Private Declare PtrSafe Function MakeSureDirectoryPathExists Lib "imagehlp.dll" (ByVal DirPath As String) As Boolean
#Else
    Private Declare Function MakeSureDirectoryPathExists Lib "imagehlp.dll" (ByVal DirPath As String) As Boolean
#End If

Sub CreateFolderStructure2()
    Dim objRow As Range, objCell As Range, strFolders As String

    For Each objRow In ActiveSheet.UsedRange.Rows
        strFolders = "C:\Users\Anthony.Martin\Documents\0-Test"
        For Each objCell In objRow.Cells
            strFolders = strFolders & "\" & objCell
        Next
        strFolders = strFolders & "\"
        MakeSureDirectoryPathExists strFolders
    Next
End Sub

**amartin575** · 10-18-2019, 11:44 AM

wow that was much much faster. Thanks.

**karedog** · 10-19-2019, 12:45 AM

You are welcome, thanks for marking the thread as solved and rep.points.

Regards

Quickly create folders and subfolders with vba

LinkBack

Thread Tools

Rate This Thread

Display

Hybrid View

Quickly create folders and subfolders with vba

Re: Quickly create folders and subfolders with vba

Re: Quickly create folders and subfolders with vba

Re: Quickly create folders and subfolders with vba

Thread Information

Users Browsing this Thread

Similar Threads

Macro to create folders and subfolders

Create folders in all the subfolders and move subfolders

[SOLVED] VBA code to add folders and subfolders

[SOLVED] Creating Folders and Subfolders

Use VBA to create hyperlinks to every file in a directory or folders and subfolders

Listing folders and subfolders

Traversing folders and subfolders

Tags for this Thread

Bookmarks

Bookmarks

Posting Permissions