Cleaner code for looping through userform controls (beginner)

I have a UserForm containing two Frames with 3 combinations of visibility/invisibility.
I have 3 separate codes to control which empty ComboBox takes the SetFocus. (see code below)
I did it this way to address the errors that were being thrown by the empty ComboBoxes in the invisible Frames.

My question is in two parts.
1. How can I make the 3 separate codes into 1?
2. What modification will I have to make when I have a UserForm with both ComboBoxes and TextBoxes?

I would appreciate help from anyone who takes the time.

'When Frame2 is invisible

 
Sub setFocus1 ()

Dim ctl as MSForms.Control

For each ctl in Frame1.Controls
If TypeName(ctl)  = "ComboBox" Then
If ctl.Text = Empty Then
ctl.SetFocus
Exit For 
End if
End if
Next ctl

End sub

'When Frame1 is invisible

 
Sub setFocus2 ()

Dim ctl as MSForms.Control

For each ctl in Frame2.Controls
If TypeName(ctl)  = "ComboBox" Then
If ctl.Text = Empty Then
ctl.SetFocus
Exit For 
End if
End if
Next ctl

End sub

'When both Frames are visible

 
Sub setFocus3 ()

Dim ctl as MSForms.Control

For each ctl in Me.Controls
If TypeName(ctl)  = "ComboBox" Then
If ctl.Text = Empty Then
ctl.SetFocus
Exit For 
End if
End if
Next ctl

End sub

Frame is just another control so you can condition test it

2.
you cannot set focus to both control box and/or text...only 1 thing can have focus? so not sure what actually want to do

anyways i setup a little test file so you can see two things
frame visible switching and focus swapping via command button

Sub setFocus4()
    
    Dim ctl As MSForms.Control
    
    For Each ctl In Me.Controls
        If TypeName(ctl) = "ComboBox" Then
            If ctl.Text = Empty And ctl.Parent.Visible Then
                ctl.SetFocus
                Exit For
            End If
        End If
    Next ctl
    
End Sub

This code expands on that posted by humdingaling.

I moved the setfocus loop into a function which you can pass the parent control and the type of control you want to have focus. Note this currently only works for controls that support the Text property.

Private Function m_SetFocus(Parent As Object, Name As String) As Boolean

    Dim ctl As msforms.Control
    Dim returnValue As Boolean
    
    returnValue = False
    On Error GoTo ErrSetFocus
    
    For Each ctl In Parent.Controls
        If StrComp(TypeName(ctl), Name, vbTextCompare) = 0 Then
            If ctl.Text = Empty Then
                ctl.SetFocus
                returnValue = True
                Exit For
            End If
        End If
    Next ctl

ErrSetFocus:
    m_SetFocus = returnValue
    Exit Function
End Function

Private Sub cmdSwitch_Click()

    If Me.Frame1.Visible = True Then
        Me.Frame1.Visible = False
        Me.Frame2.Visible = True
        
        ' try for a text box
        If Not m_SetFocus(Frame2, "TextBox") Then
            ' otherwise a combobox
            m_SetFocus Frame2, "ComboBox"
        End If
    Else
        Me.Frame1.Visible = True
        Me.Frame2.Visible = False
            
        m_SetFocus Frame1, "ComboBox"
    End If
    
End Sub

That's one of the best Thank Yous I seen in awhile. You're welcome.