Finding File Time

If I have, say, in a Cell the formula =Cell(FileName",A1), that generates the name of the curreent file.

Or I might have, in a Cell, a "Value" such as
="C:\MyFolder\MyFile.TXT"

How can I use this value to find the "Date / Time " stamp?

Yes, I know there are several "styles" of these -
Created, Modified, Accessed, archived, completed, last saved, received, released, sent, taken, deleted, any more ?
so I also need to be able to specify which style.

I haven't managed to find a "built-in" function - is there one ?

So - if not - some ideas, please, for a VBA Function, so that I can use the formula
= FileTime ( B3, myStyle )

And of course I would then want to modify that for FileSize, FileShortName and FileAttr ;-)

Here is a VBA that you can modify for your particular objects you wish to find. It should give you an idea of a possible direction to pursue if I am understanding your request.

Sub ListAllFile()

    Dim objFSO As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim ws As Worksheet
    Dim sPath As String
    Dim lrA As Long
    Dim lrB As Long

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set ws = Worksheets.Add

    'Get the folder object associated with the directory
    sPath = InputBox("What is the full Path to Search?")
    Set objFolder = objFSO.GetFolder(sPath)
    ws.Cells(1, 1).Value = "The files found in " & objFolder.Name & " are:"
    ws.Cells(1, 2).Value = "The files found have modified dates:"
    ws.Cells(1, 3).Value = "The file Size is:"

    'Loop through the Files collection
    For Each objFile In objFolder.Files
    'If objFile.Name Like "*.pdf" Then
        lrA = Range("A" & Rows.Count).End(xlUp).Row
        lrB = Range("B" & Rows.Count).End(xlUp).Row
        ws.Range("A" & lrA + 1).Value = objFile.Name
        ws.Range("B" & lrB + 1).Value = objFile.DateLastModified
        ws.Range("C" & lrB + 1).Value = objFile.Size
    'End If
    Next
    'ws.Cells(2, 1).Delete
    'Clean up!
    Set objFolder = Nothing
    Set objFile = Nothing
    Set objFSO = Nothing

End Sub

You can access following 3 datetime using Scripting.FileSystemObject.
DateCreated, DateLastModified, DateLastAccessed

Archived is just an attribute on the file object and note datetime. Assuming it was archived, then last modified should be the archived date.
Other datetime / attributes you listed, does not exist in file object record.

Ex:

Public Function GetFileDates(strFile As String, dType As Integer)
Dim oFS As Object
Set oFS = CreateObject("Scripting.FileSystemObject")

Select Case dType
    Case Is = 1
        temp = oFS.GetFile(strFile).DateCreated
    Case Is = 2
        temp = oFS.GetFile(strFile).DateLastModified
    Case Is = 3
        temp = oFS.GetFile(strFile).DateLastAccessed
    Case Else
        temp = "Invalid dType, select 1 to 3"
End Select

GetFileDates = temp
    
End Function