Function not working when used in userform

So to start, I'm super new at this and barely know what I'm doing. I'm trying to make a tracking sheet for logs that I get delivered to my sawmill. Ideally one of my employees can enter in the log characteristics in the userform and it will be transferred to a table to be tallied. I set up some if statements to choose a price based on species and grade. It works as intended when entered into a cell, however I was having trouble figuring out how to select the next row without the row being empty, so I had to remove the if statements and try to put them into the userform. When entered, I get a compile error for end of statement.

Any tips on how to fix this or generally set it up better?

Private Sub cbNext_Click()
'Find Empty Row
Dim rw As Integer
Dim ws As Worksheet

Set ws = Worksheets("Table")

rw = ws.Cells.Find(What:="*", SearchOrder:=xlRows, SearchDirection:=xlPrevious, LookIn:=xlFormulas).Row + 1

'Submit log data
ws.Cells(rw, 1).Value = Me.SpeciesList.Value
ws.Cells(rw, 2).Value = Me.tbLength.Value
ws.Cells(rw, 3).Value = Me.tbDiameter.Value
ws.Cells(rw, 4).Value = Me.tbSweep.Value
ws.Cells(rw, 5).Value = Me.tbCrook.Value
ws.Cells(rw, 6).Value = Me.LogGrades.Value
ws.Cells(rw, 7).Value = "=(((Table!C6-4)^2)*Table!B6)/16"
ws.Cells(rw, 8).Value = "=IF(F6="Tie",IF(A6="White Oak",Master!$B$5,IF(A6="Red Oak",Master!$B$5,Master!$B$2)),IF(F6="Blocking",Master!$B$3,IF(F6="Pallet",Master!$B$4,"-")))"
ws.Cells(rw, 9).Value = "=IF(H6=" - "," - ",H6*G6)"

Unload Me
Logs.Show

End Sub

Hi, It's difficult to say if this would work without seeing a sample file, but try this slight rework of your code.

Private Sub cbNext_Click()
    Dim rw As Integer
    Dim ws As Worksheet:        Set ws = Worksheets("Table")
    
    'Find Empty Row
    rw = ws.Cells.Find(What:="*", SearchOrder:=xlRows, SearchDirection:=xlPrevious, LookIn:=xlFormulas).Row + 1
    
    'Submit log data
    With ws
        .Cells(rw, 1).Value = Me.SpeciesList.Value
        .Cells(rw, 2).Value = Me.tbLength.Value
        .Cells(rw, 3).Value = Me.tbDiameter.Value
        .Cells(rw, 4).Value = Me.tbSweep.Value
        .Cells(rw, 5).Value = Me.tbCrook.Value
        .Cells(rw, 6).Value = Me.LogGrades.Value
        .Cells(rw, 7).Formula = "=(((Table!C" & rw & "-4)^2)*Table!B" & rw & ")/16"
        .Cells(rw, 8).Formula = "=IF(F" & rw & "=""Tie"",IF(A" & rw & "=""White Oak"",Master!$B$5,IF(A" & rw & "=""Red Oak"",Master!$B$5,Master!$B$2)),IF(F" & rw & "=""Blocking"",Master!$B$3,IF(F" & rw & "=""Pallet"",Master!$B$4,""-"")))"
        .Cells(rw, 9).Formula = "=IF(H" & rw & "=""-"",""-"",H" & rw & "*G" & rw & ")"
    End With
    
    Unload Me
    Logs.Show
End Sub

B.

That worked perfectly, thank you.