Copying data from excel into Word

Without seeing your updated code - especially for the font - it's impossible to know what the issue is. That said, the way you're adding content to the bookmarks means that you can't format the added content. For code to update a bookmarked range so that the update is accessible via the bookmark, try:

Sub Procedure1()
Dim objWord As Object, objDoc As Object
Dim ws As Worksheet
Set ws = ThisWorkbook.Sheets("Sheet6")
Set objWord = CreateObject("Word.Application")
objWord.Visible = True
Set objDoc = objWord.Documents.Open("C:\Users\Christopher.Ellis\Test1.docx") ' change as required
Call UpdateBookmark(objDoc, "CN1", ws.Range("C25").Text)
Call UpdateBookmark(objDoc, "CN2", ws.Range("C25").Text)
Call UpdateBookmark(objDoc, "CNo1", ws.Range("C26").Text)
Call UpdateBookmark(objDoc, "Cl1", ws.Range("C27").Text)
Call UpdateBookmark(objDoc, "Ex_1", ws.Range("C28").Text)
Call UpdateBookmark(objDoc, "Ex_2", ws.Range("C28").Text)
objDoc.Close True
Set objDoc = Nothing: Set objWord = Nothing: Set ws = Nothing
End Sub

Sub UpdateBookmark(objDoc As Object, StrBkMk As String, StrTxt As String)
Dim BkMkRng As Object
With objDoc
  If .Bookmarks.Exists(StrBkMk) Then
    Set BkMkRng = .Bookmarks(StrBkMk).Range
    BkMkRng.Text = StrTxt
    .Bookmarks.Add StrBkMk, BkMkRng
  End If
End With
Set BkMkRng = Nothing
End Sub

If you apply the desired font characteristics to the bookmarks before updating them, they should apply to whatever's inserted there. Otherwise, after updating the content, you could use code like:

With objDoc.Bookmarks("CN2").Range.Font
  .Name = "Tahoma"
  .Size = 9
End With

Originally Posted by chrisellis250

My word template has text in the bookmarks, but when my code runs it doesn't keep the font the same as in the template.

When you're writing a string to a document, regardless of the source of that string, it takes on the formatting characteristics of the range it's written to. That said, you're also not creating a document from a Word template - you're merely opening an existing Word document.

Originally Posted by chrisellis250

Where in the code that you have posted do I put the code to set the font?

You might put it immediately after the corresponding Call statement, or anywhere between there and:
objDoc.Close True

Cross-posted at: https://stackoverflow.com/questions/...35704#56435704 without even the courtesy of acknowledging the help - and comprehensive answer - you've already received here.
Kindly read Excel Forum's Cross-Posting policy in rule 8: http://www.excelforum.com/forum-rule...rum-rules.html