Trouble reading values from a two dimensional array

Good afternoon -

Spending some time today working on my VBA skills and struggling with two diensional arrays. Thanks in advance for any help.

Simply put, I'm trying to compare values in column A with values in a 2D array. When there is a match, I want to turn the value in column A to a bold font. Here's my code and attached is my practice workbook.

Sub Practice8()

'THE PURPOSE IS TO COMPARE THE VALUES IN COLUMN A WITH THE _
VALUES IN THE ARRAY (i.e., Sheet2, Range C1:D3) AND WHENEVER A _
MATCH IS FOUND, TURN THE VALUE IN COLUMN A TO BOLD

Dim Arr() As Variant
Arr = Range("C1:D3")
Dim r As Long
Dim c As Long

With Sheet2

    For r = 1 To UBound(Arr, 1)
        For c = 1 To UBound(Arr, 2)
              
         Next c
        
    Next r
    
Dim i As Long
Dim Rows As Long

    For i = 1 To 4

        If Cells(i, 1) = (r) & (c) Then
        Cells.Font.Bold = True
                         
        End If

    Next i

End With

End Sub

A different way:

Option Explicit

Sub array_compare()
    Dim c As Integer, r As Long, rws As Long, what, fnd
    With Sheet2
        r = 1: rws = .Range("C1").CurrentRegion.Rows.Count
        Do Until .Cells(r, "A").Value = ""
            c = 3: what = .Cells(r, "A").Value
            Do Until .Cells(1, c).Value = ""
                fnd = Application.Match(what, .Range(.Cells(1, c), .Cells(rws, c)), 0)
                If Not IsError(fnd) Then .Cells(r, "A").Font.Bold = True: Exit Do
                c = c + 1
            Loop
            r = r + 1
        Loop
    End With
End Sub

Not a good example to practice...

You can do For Each Loop within an array when you only need to READ the elements, not EDIT.
And it moves by dimension, so 1st C1:C3 and then D1:D3 unlike For Each Loop in a Range.

Sub Practice8()
    Dim Arr() As Variant, e, r As Range
    Arr = Range("C1:D3")
    For Each r In Range("a1", Range("a" & Rows.Count).End(xlUp))
        For Each e In Arr
            If r.Value = e Then
                r.Font.Bold = True
                Exit For
            End If
        Next
    Next
End Sub