Filter Array 1 with Array 2 as criteria, returning filtered data to source sheet

How about

Sub FilterArr()
   Dim Rw As Long, Nrw As Long, Nc As Long
   Dim rng As Range
   Dim vaData As Variant, Var As Variant, Nary As Variant
   Dim ws As Worksheet
   Set rng = Sheet2.Range("P1:P" & Cells(Rows.Count, "P").End(xlUp).Row)
   Set ws = Sheet1
   
   Var = ws.UsedRange.Value
   vaData = rng.Value
   ReDim Nary(1 To UBound(Var), 1 To UBound(Var, 2))
   
   With CreateObject("scripting.dictionary")
      For Rw = 2 To UBound(vaData)
         .Item(vaData(Rw, 1)) = Empty
      Next Rw
      
      For Rw = 1 To UBound(Var, 1)
         If Not .exists(Var(Rw, 3)) Then
            Nrw = Nrw + 1
            For Nc = 1 To UBound(Var, 2)
               Nary(Nrw, Nc) = Var(Rw, Nc)
            Next Nc
         End If
      Next Rw
   End With
   With Sheets("Temp")
      .Cells.ClearContents
      .Range("A1").Resize(Nrw, Nc - 1).Value = Nary
   End With
End Sub

Hi Fluff
the intermediate window was giving an array of 17,000 to 1 when it should have have been 30 entries so I thought was not reading vadata array.

Made this change to check and no it copies without filtering

   Var = ws.UsedRange.Value
   'vaData = rng.Value
   vaData = Array("ABBEYROSS MANUFACTURING CO. LTD.")

is this declaring a item as empty??

   With CreateObject("scripting.dictionary")
      For Rw = 2 To UBound(vaData)
         .Item(vaData(Rw, 1)) = Empty
      Next Rw

It's filtering for me, the temp sheet has 5371 rows rather than 17139.

And yes the item is being set to empty (or "") as it's not needed.

Apologies, you are quite correct. The filtering is just the reverse of what I had in mind therefore I never spotted it.

I changed to

      For Rw = 1 To UBound(Var, 1)
         If .exists(Var(Rw, 3)) Then

and I appear to be sorted. Many thanks Fluff

Ah. My change is not correct. It does give me the entries for the 3rd item in vaData but only that. I will reverse change and see what I can do.

The change you made should show only those customers that appear in the vaData.
Is that what you want?

Glad you got it sorted & thanks for the feedback