"Object required" error upon "Exit Function" statement

I have an OpenProject function in Excel VBA that returns an Object. The purpose is to open a Microsoft Project file and return the Project as an object. The code is being written to be able to run in either Excel or Project. The OpenProject function opens the project correctly and correctly assigns it to the return value for the function. When I debug after the project is opened, I am able to use commands in the Immediate window to get the name of the project and number of tasks, so I know the object is valid.

However, when the Exit Function statement is executed I get an "Object required" error. I have seen this error occur on various statements but never on an Exit Function statement when the return object is valid. What could possibly cause this on Exit Function?

I have attached a file that has been skinnied down to the minimal code to reproduce the error.

I'm surprised that compiles; the invocation of OpenProject doesn't agree with OpenProject's signature.

Set SourceProject = OpenProject(ExcelExport_Apps.MSP)
...
Public Function OpenProject() As Object

Fix that and it works:

Set SourceProject = OpenProject()

Or early-bound,

Public appXL        As Excel.Application
Public appPr        As MSProject.Application

Public Sub Test()
  Dim SourceProject As Object  ' Project ' The Microsoft Project object we are going to export

  ' Establish applications
  Select Case Application.Name
    Case "Microsoft Excel"
      Set appXL = Application
      Set appPr = New MSProject.Application
      ' Ask the user for the project
      Set SourceProject = OpenProject()

    Case "Microsoft Project"
      Set appXL = New Excel.Application
      appXL.Visible = True
      Set appPr = Application
      ' Use the active project
      Set SourceProject = appPr.ActiveProject
  End Select

End Sub

Public Function OpenProject() As Object  ' Project
  ' Open Project and prompt the user for a Project file to open
  ' Return value is the Project object
  ' Project is left open, minimized

  appPr.FileOpen

  On Error GoTo NoProject
  Set OpenProject = appPr.ActiveProject
  Exit Function

NoProject:

  appPr.FileExit

  If Err.Number = 424 Then
    ' File not found
    MsgBox "No Project selected, exiting."

  Else
    MsgBox "Unexpected error attempting to open Project file" & vbLf & _
           "Exiting." & vbLf & _
           Err.Number & " " & Err.Description
  End If
End Function

Exit Function 'unnecessary

I believe it is necessary, otherwise the Else clause will execute.