Store userform control sizes in array to use later

Hi All

This link shows how to resize a Userform and all it's controls...
How would one adapt the size change to reset to initial open size...
https://www.rondebruin.nl/mac/mac022.htm

Edit...So saving the Initial Userform's width & height on open can work for the Userform itself...
How would one go and save the initial controls ... save into array??

So this could be quite a task...
Get initial default sizes...And then reset to initial sizes...How can i save each controls sizes to an array to call on in the reset code...

With UserForm1
    W = .Width
    H = .Height
    x = 1
    For Each ctrl In .Controls
        Debug.Print ctrl.Name
        ReDim Preserve CtrlArr(x)
        With ctrl
            On Error Resume Next
            CtrlArr(x) = .Name & "," & .Top & "," & .Left & "," & .Width & "," & .Height & "," & .Font.Size
            On Error GoTo 0
        End With
        x = x + 1
    Next ctrl
End With
For i = 0 To UBound(CtrlArr)
    Debug.Print CtrlArr(i)
Next i
End Sub

Okay, so this seems to work...Anyone else have a simpler solution...

Private Sub UserForm_Initialize()
With UserForm1
    W = .Width
    H = .Height
    x = 1
    For Each ctrl In .Controls
        ReDim Preserve CtrlArr(x)
        With ctrl
            On Error Resume Next
            CtrlArr(x) = .Name & "," & .Top & "," & .Left & "," & .Width & "," & .Height & "," & .Font.Size
            On Error GoTo 0
        End With
         x = x + 1
    Next ctrl
End With
End Sub

Reset to original size....

Private Sub CommandButton6_Click()
With UserForm1
    .Width = W
    .Height = H
    i = 1
    For Each ctrl In .Controls
        Debug.Print ctrl.Name
        With ctrl
            .Top = Trim(Split(CtrlArr(i), ",")(1))
            .Left = Trim(Split(CtrlArr(i), ",")(2))
            .Width = Trim(Split(CtrlArr(i), ",")(3))
            .Height = Trim(Split(CtrlArr(i), ",")(4))
            On Error Resume Next
            .Font.Size = Trim(Split(CtrlArr(i), ",")(5))
            On Error GoTo 0
        End With
        i = i + 1
    Next
End With
End Sub

Hello Sintek,

This might be...

Global Dict As Object

Sub SaveControlSizes()
    
    Dim Ctrl    As Object
    Dim Key     As Variant
    Dim Sizes   As Variant
    
        Set UF = UserForm1
        
        If Dict Is Nothing Then
            Set Dict = CreateObject("Scripting.Dictionary")
            Dict.CompareCmode = vbTextCompare
        End If
        
        For Each Ctrl In UF.Controls
            Key = Ctrl.Name
            If Not Dict.Exists(Key) Then
                ReDim Sizes(4)
                    Sizes(0) = Ctrl.Top
                    Sizes(1) = Ctrl.Left
                    Sizes(2) = Ctrl.Width
                    Sizes(3) = Ctrl.Height
                    Sizes(4) = Ctrl.Font.Size
                Dict.Add Key, Sizes
            End If
        Next Ctrl
    
End Sub

Sub RestoreControlSizes()

    Dim Ctrl    As Object
    Dim Key     As Variant
    Dim Sizes   As Variant
    
        Set UF = UserForm1
        
        If Dict Is Nothing Then
            MsgBox "The Control sizes have not been saved.", vbOKOnly + vbExclamation, "Resize Error"
            Exit Sub
        End If

        For Each Ctrl In UF.Controls
            Key = Ctrl.Name
            If Dict.Exists(Key) Then
                Sizes = Dict(Key)
                With Ctrl
                    .Name = Key
                    .Top = Sizes(0)
                    .Left = Sizes(1)
                    .Width = Sizes(2)
                    .Height = Sizes(3)
                    .Font.Size = Sizes(4)
                End With
            End If
        Next Ctrl
        
End Sub

Leith..You are a legend...thanks so much for the alternative...A much cleaner solution it is...

Hello sintek,

Welcome you are!