Need Macro to run on 1 sheet only

Hello, I am currently using this macro on sheet 1:

Sub Transposer()
    Dim lngR As Long
    Dim lngC As Long
    
    lngC = 2
    
    For lngR = 1 To Cells(Rows.Count, "A").End(xlUp).Row
        If Not IsNumeric(Cells(lngR, "A").Value) Then
            lngC = lngC + 1
            Cells(1, lngC).Value = Cells(lngR, "A").Value
        Else
            Cells(Rows.Count, lngC).End(xlUp)(2).Value = Cells(lngR, "A").Value
        End If
    Next lngR
Range("A:B").EntireColumn.Delete
End Sub

to turn vertical columns of data, to horizontal columns of data. When doing so it will mess up formulas I have on sheet 2. Any ideas on how to solve this problem?

Moderator's note: Please take the time to review our rules. There aren't many, and they are all important. Rule #2 requires code tags. I have added them for you this time because you are a new member. --6StringJazzer

What module is this code in? If it is in the module for Sheet1 there is nothing here that could possibly affect Sheet2.

If instead it is in a general module (like Module1) then it will operate on whatever the active sheet is. You want this code to be in the Sheet1 module.

Alternatively, if in a general module, you can explicitly qualify the references for Sheet1. Note the With clause and that I have added dots in front of all references to Cells and Range.

Sub Transposer()
    Dim lngR As Long
    Dim lngC As Long
    
    lngC = 2
    
    With Sheet1
        For lngR = 1 To .Cells(Rows.Count, "A").End(xlUp).Row
            If Not IsNumeric(.Cells(lngR, "A").Value) Then
                lngC = lngC + 1
                .Cells(1, lngC).Value = .Cells(lngR, "A").Value
            Else
                .Cells(Rows.Count, lngC).End(xlUp)(2).Value = .Cells(lngR, "A").Value
            End If
        Next lngR
        .Range("A:B").EntireColumn.Delete
    End With
End Sub