date and time format together with quarter

Hello forum,

I have output from a database and need to correct the "changed" column to correct format and also extract the year and its quarter.
Column changed has "YYMMDDHHMM" the "0" disapears when open csv file in excel for years before 2010. I need to get full "YYYYMMDDHHMM" and also the year together with the quarter.

Need to run this in a vba solution.
Attached is some samples from the database. Column B and C is the output (wanted result)

Here is the second part. Still working on the first part.

Option Explicit

Sub qtr()
    Dim i As Long, lr As Long
    Dim yr As String
    Dim qtr As String
    Application.ScreenUpdating = False
    lr = Range("B" & Rows.Count).End(xlUp).Row
    For i = 2 To lr
        yr = Left(Range("B" & i), 4)
        If Mid(Range("B" & i), 5, 2) = "01" Or Mid(Range("B" & i), 5, 2) = "02" Or Mid(Range("B" & i), 5, 2) = "03" Then
            qtr = "Q1"
        ElseIf Mid(Range("B" & i), 5, 2) = "04" Or Mid(Range("B" & i), 5, 2) = "05" Or Mid(Range("B" & i), 5, 2) = "06" Then
            qtr = "Q2"
        ElseIf Mid(Range("B" & i), 5, 2) = "07" Or Mid(Range("B" & i), 5, 2) = "08" Or Mid(Range("B" & i), 5, 2) = "09" Then
            qtr = "Q3"
        ElseIf Mid(Range("B" & i), 5, 2) = "10" Or Mid(Range("B" & i), 5, 2) = "11" Or Mid(Range("B" & i), 5, 2) = "12" Then
            qtr = "Q4"
        End If
        Range("C" & i) = yr & "-" & qtr
    Next i
    Application.ScreenUpdating = True
    MsgBox "Action completed"

End Sub

Here's the first part

Option Explicit

Sub dtetm()
    Dim i As Long, lr As Long
    lr = Range("A" & Rows.Count).End(xlUp).Row
    Application.ScreenUpdating = False
    For i = 2 To lr
        If Len(Range("A" & i)) = 9 Then
            Range("B" & i) = 200 & Range("A" & i)
        Else: Range("B" & i) = 20 & Range("A" & i)
        End If
        Range("B2:B" & lr).NumberFormat = "0"
    Next i
    Application.ScreenUpdating = True
    MsgBox "completed"
End Sub

Sub Convert_Dates()
    Dim v, i&, q$
    With Range("A2", Range("A" & Rows.Count).End(xlUp)).Resize(, 3)
        v = .Value
        For i = 1 To UBound(v, 1)
            v(i, 2) = Format(v(i, 1), "200000000000")
            Select Case Val(Mid(v(i, 2), 5, 2))
                Case Is <= 3: q = "-Q1"
                Case Is <= 6: q = "-Q2"
                Case Is <= 9: q = "-Q3"
                Case Is <= 12: q = "-Q4"
            End Select
            v(i, 3) = Left(v(i, 2), 4) & q
        Next
        .Value = v
    End With
    Columns("B").NumberFormat = "0"
End Sub

You're welcome.

Sub Convert_Dates()
    Dim v, i&, q$
    v = Range("F2", Range("F" & Rows.Count).End(xlUp)).Resize(, 2)
    For i = 1 To UBound(v, 1)
        v(i, 1) = Format(v(i, 1), "200000000000")
        Select Case Val(Mid(v(i, 1), 5, 2))
            Case Is <= 3: q = "-Q1"
            Case Is <= 6: q = "-Q2"
            Case Is <= 9: q = "-Q3"
            Case Is <= 12: q = "-Q4"
        End Select
        v(i, 2) = Left(v(i, 1), 4) & q
    Next
    Range("K2:L2").Resize(UBound(v, 1)).Value = v
    Columns("K").NumberFormat = "0"
End Sub

You're welcome. Thanks for the feedback.