Variable Range - Set Rows AND Columns as variables

Hi guys,

i Need to have a variable range for selecting shapes in a specific range on my sheet.
My Code can already shift the range on any row (easy because of Number Format). But how can i set variables instead of column letters (like A or S in the example) to enable also a shift in columns.

   dynRange = "A" & dynA & ":S" & dynS

        For Each shp1 In sheet1.Shapes
        If Not Intersect(Range(dynRange), shp1.TopLeftCell) Is Nothing Then
            shp1.Select Replace:=False
        End If
        Next shp1
        Selection.Copy

Look in the attachment for further Explanation and a sample set to try your solution on.
I appreciate any help.

Hi
Not so clear. Can you post a sample of your workbook ..
How would you like to store the variables of "A" and "S" .. in cells or in the code itself?

Do you mean something like that

Sub selectShape()
    Dim dynRange, dynA, dynS As Variant
    Dim shp1 As Shape
    Dim fC As String, eC As String

    fC = "A": eC = "O"
    dynA = 1: dynS = 30

    dynRange = fC & dynA & ":" & eC & dynS

    For Each shp1 In Tabelle1.Shapes
        If Not Intersect(Range(dynRange), shp1.TopLeftCell) Is Nothing Then
            shp1.Select Replace:=False
        End If
    Next shp1
End Sub

Try this version

Sub Select_Shapes()
    Dim dynRange    As Range
    Dim fR          As Integer   'First Row
    Dim eR          As Integer   'End Row
    Dim fC          As Integer   'First Column
    Dim eC          As Integer   'End Column
    Dim shp         As Shape

    fR = 1: eR = 30     'Change Rows To Suit
    fC = 1: eC = 15     'Change Columns To Suit

    Set dynRange = Range(Cells(fR, fC), Cells(eR, eC))

    For Each shp In Tabelle1.Shapes
        If Not Intersect(dynRange, shp.TopLeftCell) Is Nothing Then
            shp.Select Replace:=False
        End If
    Next shp
End Sub