"Worksheet_Change" from Add-In

I'm trying to run a macro for a selection change. The unique aspect ... it's in an Add-In.
I've placed the following in Sheet 1, saved the Add-In, turned on the Add-In.
It does not run.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim KeyCells As Range
    Set KeyCells = Range("A1:Z100")
    
    If Not Application.Intersect(KeyCells, Range(Target.Address)) _
           Is Nothing Then
        MsgBox "Cell " & Target.Address & " has changed."
    End If
End Sub

This seemed to work.

THIS WORKBOOK

Option Explicit

Private XLApp As clsExcelApp

Private Sub Workbook_AddinInstall()
    Set XLApp = New clsExcelApp
End Sub


Private Sub Workbook_Open()
    Set XLApp = New clsExcelApp
End Sub

Class module clsExcelApp

Option Explicit

Private WithEvents App As Application


Private Sub App_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Dim KeyCells As Range
    Set KeyCells = Range("A1:Z100")
    With Sh

    If Not Application.Intersect(KeyCells, Range(Target.Address)) _
           Is Nothing Then
        MsgBox "Cell " & Target.Address & " has changed."
    End If
    End With

End Sub

Private Sub Class_Initialize()
    Set App = Application
End Sub