New command button

Perhaps

Private Sub CommandButton1_Click()
Dim rowNum As Integer
    On Error Resume Next
    rowNum = Application.InputBox(Prompt:="Enter Row Number where you want to add a row:", _
                    Title:="New Staff", Type:=1)
    If rowNum < 1 then Exit Sub: Rem cancel pressed
    ActiveSheet.Rows(rowNum & ":" & rowNum).Insert Shift:=xlDown
    Sheets("otherSheet").Rows(rowNum & ":" & rowNum).Insert Shift:=xlDown
End Sub

Thank you so much for your reply, the code works it enters the new row... except it does not enter the staff name to the other sheet.

There is no mention of a staff name in the OP, either the text of your question or in the code.
Where does one find the staff name, where do you want it to go (which column of the added row)?

Where does the staff name come from?
Do you want another InputBox so the user can enter it?

Where does the staff name go? Which cell in the new row (both sheets) does it go into?

So you want a macro that does two things.
1) Add a new row to two sheets
2) The next entry in of those newly created rows should be mirrored on the other sheet. After a single entry, that mirroring should stop.
Is that a description of your need?

If that describes what you want, try putting this in the ThisWorkbook code module

Public KeyRow As String
Public keySheet As Worksheet

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If Not keySheet Is Nothing Then
        If (Sh.Name = keySheet.Name) Or (Sh.Name = "otherSheet") Then
            If Target.Cells.Count = 1 Then
                If Not Application.Intersect(Target, Sh.Range(KeyRow)) Is Nothing Then
                    Application.EnableEvents = False
                        keySheet.Range(Target.Address).Value = Target.Value
                        Me.Sheets("otherSheet").Range(Target.Address).Value = Target.Value
                    Application.EnableEvents = True
                End If
            End If
        End If
    End If
    Set keySheet = Nothing
    KeyRow = vbNullString
End Sub

And then assiging this

Sub test()
    Dim rNumber As Long
    rNumber = Application.InputBox("where the row", Type:=1)
    If rNumber < 1 Then Exit Sub
    
    ActiveSheet.Rows(rNumber).Insert
    ThisWorkbook.Sheets("otherSheet").Rows(rNumber).Insert
    
    With ActiveSheet.Rows(rNumber)
        ThisWorkbook.KeyRow = .Address
        Set ThisWorkbook.keySheet = .Parent
        .Cells(1, 1).Select
    End With
    
End Sub