Help with VBA Loops

"Chart A and B have entries in the vertical direction" What does this mean? What type of charts are they?

Charts are just a graphical depiction of data. They do not contain data. If you want to access the data that is used to make a chart then you will need to have code read that part of a worksheet, not the chart.

"I need to compare in the calculation sheet in a 2 x 2 matrix" What is "the calculation worksheet"? What kind of comparison do you want to do? What are each of the four elements in the matrix? "after each 2 x 2 matrix is solved" What do you mean by "solved"? Are you trying to solve simultaneous equations for a variable?

The description here is not specific enough to give you any actual code to do what you want. I suggest you provide an Excel file with an example of what you are describing, and a mock-up of what you want the result to look like.

The paper clip icon does not work for attachments. Instead, under the text box where you type your reply click the Go Advanced button. On the next screen scroll down and click on Manage Attachments, which will show a pop-up window to Select and Upload a file. Then close the window.

I apologize for the vague and poor description. I have attached a mock version of the set up I have.

I have Chart A and Chart B (which are really just sheets) with x and y values. I need to plug the x and y values into the calculation sheet, where the respectful value will be displayed in C6 on the Calculation sheet. I need to take that value in C6, and plus it into its place on the Output Sheet. For example, if I wanted to compared ID 1's values (from A Chart) to Place 2 values (from B Chart), I want the resulting number to go in the C2 spot on the Output sheet. I need this process to repeat so that every ID and Place values are compared.

Here is my code, but it doesn't work how I want it to. This is from the actual worksheet, so the cell references are a bit off:

Dim i As Integer
Dim j As Integer

j = 2
Do While j < 4
    Worksheets("A Chart").Cells(j, 2).Copy Worksheets("Calculations").Range("B6")
    Worksheets("A Chart").Cells(j, 3).Copy Worksheets("Calculations").Range("C6")
i = 2
Do While i < 4
    Worksheets("B Chart").Cells(i, 3).Copy Worksheets("Calculations").Range("B7")
    Worksheets("B Chart").Cells(i, 4).Copy Worksheets("Calculations").Range("C7")
    x = 2
    y = 5
    Worksheets("Calculations").Range("B11").Copy Worksheets("Output").Cells(x, y)
    y = y + 1
    i = i + 1
Loop
j = j + 1
x = x + 1
Loop

Also not opposed to simply by passing the calculations sheet and just doing the calculation in the VBA coding -just not sure how to recreate the formula.

Hope this is more clear. I really appreciate your help!

Kara

Moderator's note: Please take the time to review our rules. There aren't many, and they are all important. Rule #3 requires code tags. I have added them for you this time because you are a new member. --6StringJazzer

Option Explicit
Sub distchart()
    Dim CHARTA          As Worksheet, _
        CHARTB          As Worksheet, _
        CALCS           As Worksheet, _
        OUTPUT          As Worksheet, _
        ID_Data         As Variant, _
        ID_Ptr          As Long, _
        ID_x            As Double, _
        ID_y            As Double, _
        Place_Data      As Variant, _
        Place_Ptr       As Long, _
        Place_x         As Double, _
        Place_y         As Double
        
    Set CHARTA = Worksheets("A Chart")
    Set CHARTB = Worksheets("B Chart")
    Set CALCS = Worksheets("Calculation")
    Set OUTPUT = Worksheets("output")
    
    ID_Data = CHARTA.Range("a_chart").Value
    Place_Data = CHARTB.Range("b_chart").Value
    
    ReDim OutputTable(1 To UBound(ID_Data), 1 To UBound(Place_Data))
    
    For ID_Ptr = 1 To UBound(ID_Data)
        ID_x = ID_Data(ID_Ptr, 1)
        ID_y = ID_Data(ID_Ptr, 2)
        
        For Place_Ptr = 1 To UBound(Place_Data)
            Place_x = Place_Data(Place_Ptr, 1)
            Place_y = Place_Data(Place_Ptr, 2)
            
            OutputTable(ID_Ptr, Place_Ptr) = Evaluate("Acos((Cos(Radians(90 - " & ID_x & ")) * Cos(Radians(90 - " & Place_x & ")) + Sin(Radians(90 -" & ID_x & ")) * Sin(Radians(90 - " & Place_x & ")) * Cos(Radians(" & ID_y - Place_y & ")))) * 6371 * 0.6214")
        
        Next Place_Ptr
    Next ID_Ptr
    
    OUTPUT.Range("b2").Resize(RowSize:=UBound(ID_Data), ColumnSize:=UBound(Place_Data)).Value = OutputTable
End Sub

---

A_Chart ='A Chart'!$B$2:INDEX('A Chart'!$C:$C,COUNTA('A Chart'!$C:$C))
B_Chart ='B Chart'!$B$2:INDEX('B Chart'!$C:$C,COUNTA('B Chart'!$C:$C))