Jagged Array vba

I am curious what your research turned up that you found difficult to understand. I would expect something like this?

Sub test()
stop 'stop statement enters debug mode so you can step through the function and examine variables as stuff happens.
Dim varproject(1 To 3) As Variant
varproject(1) = Array("a", "b", "c")
varproject(2) = Array("d")
varproject(3) = Array("e", "f")
For i = 1 To 3
Debug.Print varproject(i)(0)
Next i
End Sub

Note that I can control the lower limit for the outer varproject() array, but the inner "variants containing arrays" will default to a 0 based array, which is why I used 0 as the index for the first element of each inner array.

Hello
This may help you .. I suppose you have two columns of data A & B ..

Sub Test()
    Dim a           As Variant
    Dim i           As Long
    Dim j           As Long
    Dim x           As Long

    a = Range("A1").CurrentRegion.Value

    For i = 2 To UBound(a)
        x = IIf(UBound(Split(a(i, 2), " ")) + 1 > x, UBound(Split(a(i, 2), " ")) + 1, x)
    Next i
    ReDim b(1 To UBound(a, 1) - 1, 1 To x + 1)
    
    For i = 2 To UBound(a)
        b(i - 1, 1) = a(i, 1)
        For j = 1 To UBound(Split(a(i, 2), " ")) + 1
            b(i - 1, j + 1) = Split(a(i, 2), " ")(j - 1)
        Next j
    Next i
    
    Debug.Print b(1, 2)     'John
    Debug.Print b(2, 2)     'Peter
    Debug.Print b(3, 2)     'Sarah
    Debug.Print b(3, 3)     'Peter
End Sub

As wanted lol...just to be playful

Option Explicit
Sub Arr()
Dim ProjArr, i As Long, ii As Long
ProjArr = Array("John Peter", "Peter", "Sarah Peter John")
For i = 0 To UBound(ProjArr)
    If i = 2 Then ii = 1 Else ii = 0
    Debug.Print Split(ProjArr(i))(ii)
Next i
End Sub

Another option !!!
Data start "A1":- NB:- Project and names split into columns/rows as below

var_Project var_Name
Project 1 John Peter
Project 2 Peter
Project 3 Sarah Peter John


Result start "K11"

Sub MG12Jul57
Dim a() As Variant, i As Long, j As Long
Dim Rng As Range, Dn As Range
Set Rng = Range("A2", Range("A" & Rows.Count).End(xlUp))
Dim Lst As Long
ReDim a(1 To Rng.Count)

    For i = 1 To Rng.Count
        Lst = Cells(i + 1, Columns.Count).End(xlToLeft).Column
            a(i) = MakeArray(1, Lst)
            For j = 1 To Lst
                a(i)(j) = Rng(i, j)
            Next j
    Next i

Dim n As Long, Col As Long
For n = 1 To UBound(a)
    For Col = 1 To UBound(a(n))
        Cells(n + 10, Col + 10) = a(n)(Col)
    Next Col
Next n

End Sub

Function MakeArray(lower As Long, upper As Long) As Variant
Dim B As Variant
ReDim B(lower To upper)
MakeArray = B
End Function

Regards Mick

How about using a dictionary?