Replacing values from a Cell by Reference values

Hello

Is it possible to replace multiple comma separated values in excel cell by values in reference column?

Please refer the attachment.

Example
If I type A2, A5 in cell C2 then it should replace the value as Apple, Dog.

To Sheet1 code module

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim r As Range, x, i As Long
    If Intersect(Target, Columns("c")) Is Nothing Then Exit Sub
    Application.EnableEvents = False
    For Each r In Intersect(Target, Columns("c"))
        If r.Row > 1 Then
            If r.Value <> "" Then
                x = Split(r.Value, ",")
                For i = 0 To UBound(x)
                    x(i) = Trim$(x(i))
                    If IsAddress(x(i)) Then x(i) = Range(x(i)).Value
                Next
                r.Value = Join(x, ", ")
            End If
        End If
    Next
    Application.EnableEvents = True
End Sub

Function IsAddress(ByVal txt As String) As Boolean
    With CreateObject("VBScript.RegExp")
        .Pattern = "^[a-zA-Z]+\d+$"
        IsAddress = .test(txt)
    End With
End Function

' OR "^[a-zA-Z]{1,3}\d+$" to make sure max three column letters are accepted only as valid address

Not good enough

e.g
xxx100000000000000000000000

this activates userform if any cell in column C is selected

Private Sub CommandButton1_Click()
Unload Me
End Sub

Private Sub ListBox1_Click()
If ActiveCell = "" Then
    ActiveCell = ListBox1.Value
Else
    ActiveCell = ActiveCell & ", " & ListBox1.Value
End If
End Sub

Private Sub UserForm_Initialize()
With Sheets("Sheet1")
    lr = .Range("A" & Rows.Count).End(xlUp).Row
    ReDim arr(1 To lr - 1, 1 To 2)
    For i = 2 To lr
        arr(i - 1, 1) = .Cells(i, 1).Value
        arr(i - 1, 2) = .Cells(i, 1).Address(0, 0)
    Next
    ListBox1.List = arr
End With
End Sub

Kind regards
Leo