Hiding columns in excel

Can you provide a sample Excel file that represent what your Excel sheet is going to look like?

Press Alt-F11 to open the Visual Basic Editor.

Click Insert > Module.

In the module which is created, paste the following code, and change the lRow and sHide values to suit your requirement:

Sub HideColumnsByValue()
    
    'change this number to the row you wish to check
    Const lRow As Long = 8
    
    'change this text to the value for which the column should be hidden
    Const sHide As String = "DON'T PRINT"
    
    Dim c As Range
    
    On Error GoTo Terminate
    
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With
    
    With ActiveSheet
        For Each c In Intersect(.UsedRange, .Rows(lRow)).Cells
            c.EntireColumn.Hidden = c.Value = sHide
        Next c
    End With
    
Terminate:
    If Err Then
        Debug.Print "Error", Err.Number, Err.Description
        Err.Clear
    End If
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Close the Visual Basic Editor to return to Excel.

Press Alt-F8, select "HideColumnsByValue" and click "Run"


If you want to show all columns again, you could add this code to the module in the Visual Basic Editor, and run the macro "UnhideAllColumns":

Sub UnhideAllColumns()
    ActiveSheet.UsedRange.EntireColumn.Hidden = False
End Sub

Who are you thanking - which solution worked for you?

You can using manipulate

sub test()
[a1:b1] = array("a","b")
With rows("8:8")
 .replace "DON'T PRINT","=a1*b1"
 .specialcells(xlformulas,xlerrors).entirecolumn.hidden = true
End with
End sub

I don't see a solution from JieJenn, only a suggestion to attach your workbook?

Originally Posted by bsesender

i would like some help hiding columns as well, do i need to start my own thread?

Yes.



Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.