Carriage returns (Enter) in a range

Are those multiple sentences inside the same cell or 2 cells each with a sentence?

So would this get us there?
- remove ALL line breaks
- insert line break after every full stop (Period)

Do you want an empty line between each sentence?

Sub test()
Dim y(), rg As Range, x, a, s, rw&, ii As Long, i As Long
    Set rg = Range("A1", Cells(Rows.Count, 1).End(3))
    x = rg.Value
    ReDim y(1 To rg.Rows.Count, 1 To 1)
    For ii = 1 To rg.Rows.Count
        rw = rw + 1
        a = Split(x(ii, 1), Chr(10))
                 For i = 0 To UBound(a, 1)
                       s = IIf(s = "", a(i), s & " " & a(i))
                 Next i
       y(rw, 1) = s: s = ""
    Next ii
 rg.Resize(UBound(y, 1), 1).Value = y
End Sub

Here is an better example of cell content:

"The Cisco Smart Install (SMI) feature is enabled on the remote host.
If the SMI Client role enabled, it is subject to protocol misuse,
which could allow an unauthenticated, remote attacker to:

  - Substitute the switch's startup-config file with a file that the
    attacker prepared and force a reload of the switch after a defined
    time interval.

  - Load the attacker-supplied IOS image onto the switch.

  - Execute high-privilege configuration mode CLI commands on the
    switch, including do-exec CLI commands.

  - Copy arbitrary files from the switch to the attacker-controlled
    TFTP server."

Which would be better worded as:

"The Cisco Smart Install (SMI) feature is enabled on the remote host. If the SMI Client role enabled, it is subject to protocol misuse, which could allow an unauthenticated, remote attacker to:

  - Substitute the switch's startup-config file with a file that the attacker prepared and force a reload of the switch after a defined time interval.
  - Load the attacker-supplied IOS image onto the switch.
  - Execute high-privilege configuration mode CLI commands on the switch, including do-exec CLI commands.
  - Copy arbitrary files from the switch to the attacker-controlled TFTP server."

So to your questions:
- remove ALL line breaks - Not ALL. Perhaps it should be only if the break is preceded by anything other than period or semicolon, then delete the break.
- insert line break after every full stop (Period) - This could be modified so if it is a period (or a colon or semicolon) followed by two consecutive breaks, then leave the period, but only remove one of the two breaks.
Do you want an empty line between each sentence? - No, as shown by the example.

As for my original items.

1. delete a char(10) - same as your first item - I really shouldn't do this one.
2. replace char(10) followed by a space with only one space - Think this would be better that if the sentence beings with " - " and ends with two chr(10), replace with only one chr(10).
3. replace two consecutive char(10) with only one char(10) - this one should probably be skipped as it could create other issues.

Besides the example above, another is:

This test gives some information about the remote HTTP protocol - the
version used, whether HTTP Keep-Alive and HTTP pipelining are enabled,
etc... 

This test is informational only and does not denote any security
problem.

Which should look like:

This test gives some information about the remote HTTP protocol - the version used, whether HTTP Keep-Alive and HTTP pipelining are enabled, etc... 

This test is informational only and does not denote any securityproblem.

Maybe it would be easiest to just have it:

• if one break, delete it
• if two breaks, delete only one
• if three breaks, delete only one

See how close this gets you
Run from cell containing the text
Amended text is dumped in adjacent cell to right
Make sure receiving cell is a sensible width to prevent ridiculous row heights

Sub Test()
    With ActiveCell
        .Offset(, 1).Value = CleanTrim(.Value)
    End With
End Sub
Function CleanTrim(ByVal s As String) As String
    Dim X As Long, CodesToClean As Variant
    s = Replace(s, Chr(13), Chr(10))
    s = Replace(s, Chr(160), Chr(32))
    s = Replace(s, Chr(10) & Chr(10), "|||")
    s = Replace(s, Chr(10), Chr(32))
    s = Replace(s, "|||", Chr(10))
    CleanTrim = WorksheetFunction.Trim(s)
End Function

(May need to insert an additional line break after a period and a colon etc)

OR
If you place above code in a general module, the function can be used in a normal Excel formula
So with text in cell A1, and this formula in B1

Formula:

=cleantrim(A1)

Perfect! Thank you! I just modified the sub to overwrite (now that it's been tested) to:

Sub Test()
    With ActiveCell
        ' .Offset(, 1).Value = CleanTrim(.Value)
        .Value = CleanTrim(.Value)
    End With
End Sub

When I select multiple cells, if I run the code as is, it only runs on the first cell. How do I get it to loop through each one? If I modify to below, I get a compile error (invalid or unqualified reference) with the bold:

Sub Test()
    Dim cell As Range
    For Each cell In Selection
        .Value = CleanTrim(.Value)
    Next cell
End Sub

Try this - overwrites selected cells

Sub Test()
    For Each cel In Selection
        With cel
            .Value = CleanTrim(.Value)
        End With
    Next cel
End Sub