Excel VBA to convert word file to pdf

Your screenshot suggests the PDFs will have the same names & extensions as the documents. Don't do that! At least your attached workbook has the correct extensions. Try:

Sub CreatePDFs()
'Note: this code requires a reference to the Word object model. See under the VBE's Tools|References.
Application.ScreenUpdating = False
Dim wdApp As New Word.Application, wdDoc As Word.Document
Dim WkSht As Worksheet, r As Long
'Disable any auto macros in the documents being processed
wdApp.WordBasic.DisableAutoMacros
Set WkSht = ActiveSheet
With WkSht
  For r = 1 To .UsedRange.Cells.SpecialCells(xlCellTypeLastCell).Row
    If Trim(.Range("C" & r).Text) <> "" Then
      If Dir(.Range("C" & r).Text, vbNormal) <> "" Then
        Set wdDoc = wdApp.Documents.Open(.Range("C" & r).Text, AddToRecentFiles:=False, Visible:=False)
        With wdDoc
          .SaveAs Filename:=.Range("E" & r).Text, FileFormat:=wdFormatPDF, AddToRecentFiles:=False
          .Close SaveChanges:=False
        End With
      End If
    End If
  Next
End With
wdApp.Quit
Set wdDoc = Nothing: Set wdApp = Nothing: Set WkSht = Nothing
Application.ScreenUpdating = True
End Sub

Originally Posted by adekinteristi

it says that the word file is locked for editing. but i think i don't locked the file
do you know why it's locked?

You probably have an orphaned Word session that still has a document open. Close Word, then use the Task Manager to kill all remaining Word sessions.

OK, change that line to:

.SaveAs2 Filename:=WkSht.Range("E" & r).Text, FileFormat:=wdFormatPDF, AddToRecentFiles:=False

It does for me...

Check that your file paths & names are correct.

The code is using early binding. Make sure you have set reference to MS Word Object Library in References. Otherwise wdFormatPDF is unknown to excel (i.e. that is constant from Word object model)
see https://support.microsoft.com/en-us/...-in-automation