Clearing the Intermediate Window in VBA

Hello
Try this code

Private Declare Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function GetKeyboardState Lib "user32" (pbKeyState As Byte) As Long
Private Declare Function SetKeyboardState Lib "user32" (lppbKeyState As Byte) As Long
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Private Const WM_KEYDOWN As Long = &H100
Private Const KEYSTATE_KEYDOWN As Long = &H80

Private savState(0 To 255) As Byte

Sub Clear_Immediate_Window_Using_API()
'Adapted By KeepITcool
'Original From Jamie Collins FKA "OneDayWhen"
'http://www.*****-blog.com/excel/2004/06/clear_the_immed.html
'------------------------------------------------------------
    Dim hPane As Long
    Dim tmpState(0 To 255) As Byte

    hPane = GetImmHandle
    If hPane = 0 Then MsgBox "Immediate Window Not Found."
    If hPane < 1 Then Exit Sub

    'Save The Keyboardstate
    GetKeyboardState savState(0)

    'Sink The CTRL (Note We Work With The Empty tmpState)
    tmpState(vbKeyControl) = KEYSTATE_KEYDOWN
    SetKeyboardState tmpState(0)

    'Send CTRL+End
    PostMessage hPane, WM_KEYDOWN, vbKeyEnd, 0&

    'Sink The SHIFT
    tmpState(vbKeyShift) = KEYSTATE_KEYDOWN
    SetKeyboardState tmpState(0)

    'Send CTRL+SHIFT+Home And CTRL+SHIFT+BackSpace
    PostMessage hPane, WM_KEYDOWN, vbKeyHome, 0&
    PostMessage hPane, WM_KEYDOWN, vbKeyBack, 0&


    'Schedule Cleanup Code To Run
    Application.OnTime Now + TimeSerial(0, 0, 0), "DoCleanUp"
End Sub

Sub DoCleanUp()
'Restore Keyboard State
'----------------------
    SetKeyboardState savState(0)
End Sub

Function GetImmHandle() As Long
'This Function Finds The Immediate Pane And Returns A Handle
'Docked Or MDI, Desked Or Floating, Visible Or Hidden
'------------------------------------------------------------
    Dim oWnd As Object, bDock As Boolean, bShow As Boolean
    Dim sMain$, sDock$, sPane$
    Dim lMain&, lDock&, lPane&


    On Error Resume Next
    sMain = Application.VBE.MainWindow.Caption

    If Err <> 0 Then
        MsgBox "No Access to Visual Basic Project"
        GetImmHandle = -1
        Exit Function
        ' Excel2003: Registry Editor (Regedit.exe)
        '    HKLM\SOFTWARE\Microsoft\Office\11.0\Excel\Security
        '    Change Or Add A DWORD Called 'AccessVBOM' >> Set To 1

        ' Excel2002: Tools/Macro/Security
        '    Tab 'Trusted Sources', Check 'Trust Access..'
    End If


    For Each oWnd In Application.VBE.Windows
        If oWnd.Type = 5 Then
            bShow = oWnd.Visible
            sPane = oWnd.Caption
            If Not oWnd.LinkedWindowFrame Is Nothing Then
                bDock = True
                sDock = oWnd.LinkedWindowFrame.Caption
            End If
            Exit For
        End If
    Next oWnd

    lMain = FindWindow("wndclass_desked_gsk", sMain)

    If bDock Then
        'Docked Within The VBE
        lPane = FindWindowEx(lMain, 0&, "VbaWindow", sPane)

        If lPane = 0 Then
            'Floating Pane Which May Have Its Own Frame
            lDock = FindWindow("VbFloatingPalette", vbNullString)
            lPane = FindWindowEx(lDock, 0&, "VbaWindow", sPane)

            While lDock > 0 And lPane = 0
                lDock = GetWindow(lDock, 2)
                lPane = FindWindowEx(lDock, 0&, "VbaWindow", sPane)
            Wend
        End If
    ElseIf bShow Then
        lDock = FindWindowEx(lMain, 0&, "MDIClient", _
                             vbNullString)
        lDock = FindWindowEx(lDock, 0&, "DockingView", _
                             vbNullString)
        lPane = FindWindowEx(lDock, 0&, "VbaWindow", sPane)
    Else
        lPane = FindWindowEx(lMain, 0&, "VbaWindow", sPane)
    End If

    GetImmHandle = lPane
End Function

Or simply you can use sendkeys

Sub Clear_Immediate_Window_Using_SendKeys()
    Dim x As Long

    For x = 1 To 10
        Debug.Print x
    Next x

    Debug.Print Now
    
    Debug.Print String(65535, vbCr)
    'OR
    'Application.SendKeys "^g ^a {DEL}"
End Sub

Tried both of the previous posts. Didn't work. The "Code" one didn't clear the Intermediate
window but also caused the running VBA program to reset back to programming level as well.

The first solution as I mentioned in the original report didn't work unless there wa
s a "Stop" command between the "SendKeys" line and the "Debug.Print" command.

My solution was to put a "Stop" command into my "Debug_Print" routine. Then when I pressed
the "Jump back to the calling program" key, I ended up at the line after the call in th
e calling program.

 Sub Debug_Print(Message, _
                  Optional Short_Comment = "")
    ' IF Trace() Then clears the INTERMEDIATE Pane priot to _
      displaying "Message" and "Short_Comment""'.
    ' 12/10/17 Created. Mac Lingo
    
    Prog = "Debug_Print"
    
    If Trace() Then
    
        Application.SendKeys "^g ^a {DEL}"
        Stop
        
         If Short_Comment <> "" Then
            Debug.Print Short_Comment
            Debug.Print "===========================================" & _
                        "==================="
        End If

        Debug.Print Chr(10) & Message
        
        Debug.Print "===========================================" & _
                    "==================="
    End If