VBA Excel: Identifying a row, then comparing columns in that row and deleting duplicates

The aim in mind is to identify a row that has 'US Control Injection'
Then compare cell A, Cell F, Cell H and Cell O with all other rows.
Any rows that match all 4 of these cells can then be deleted along with the originally identified row.
I need to match so many cells as these can differ and i may not want to remove them.

Attached is an example file (Obviously with sterilised data)
If the code works properly then I would expect Rows 7,8 and 11,12 to be removed but all others to remain.
Apologies for not having any code to work from, normally I can adapt other code with my limited knowledge but in this case I don't know where to start.

Try this:-

Sub MG24Aug38
Dim Rng As Range, Dn As Range, n As Long, txt As String
Dim K As Variant, Fd As Boolean, Q As Variant, nRng As Range

Application.ScreenUpdating = False
Set Rng = Range(Range("A2"), Range("A" & Rows.Count).End(xlUp))

With CreateObject("scripting.dictionary")
.CompareMode = vbTextCompare
For Each Dn In Rng
    Fd = False
    txt = Join(Application.Index(Dn.Resize(, 15).Value, 0, Array(1, 6, 8, 15)), ",")
    If Dn.Offset(, 4) = "US Control Injection" Then Fd = True
    If Not .Exists(txt) Then
        n = n + 1
        .Add txt, Array(Dn, Fd)
    Else
        Q = .Item(txt)
            If Fd Then Q(1) = True
            Set Q(0) = Union(Q(0), Dn)
       .Item(txt) = Q
End If
Next
For Each K In .keys
    If .Item(K)(1) = True Then
        If nRng Is Nothing Then
            Set nRng = .Item(K)(0)
        Else
            Set nRng = Union(nRng, .Item(K)(0))
        End If
    End If
Next K
If Not nRng Is Nothing Then
    nRng.EntireRow.Delete
End If
End With
Application.ScreenUpdating = False
End Sub

Regards Mick

Thanks,

This seems to do the trick. I will apply to a much larger sheet and go through some verification but looks very promising.

Thanks again for your help

Thanks,

I'm not sure what is playing up column O.
The great thing this is a code I can apply to different criteria on other spreadsheets should i need to.